From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-sound/picard/picard-1.3.2-r1.ebuild | 49 +++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 media-sound/picard/picard-1.3.2-r1.ebuild

(limited to 'media-sound/picard/picard-1.3.2-r1.ebuild')

diff --git a/media-sound/picard/picard-1.3.2-r1.ebuild b/media-sound/picard/picard-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..1592652f1fdd
--- /dev/null
+++ b/media-sound/picard/picard-1.3.2-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+DISABLE_AUTOFORMATTING=true
+inherit eutils distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="A cross-platform music tagger"
+HOMEPAGE="http://picard.musicbrainz.org/"
+SRC_URI="http://ftp.musicbrainz.org/pub/musicbrainz/picard/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="+acoustid +cdda nls"
+
+DEPEND="dev-python/PyQt4[X,${PYTHON_USEDEP}]
+	dev-qt/qtgui:4[accessibility]
+	media-libs/mutagen
+	acoustid? ( >=media-libs/chromaprint-1.0[tools] )
+	cdda? ( dev-python/python-discid )"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test" # doesn't work with ebuilds
+S=${WORKDIR}/${PN}-release-${PV}
+DOCS="AUTHORS.txt NEWS.txt"
+
+src_compile() {
+	distutils-r1_src_compile $(use nls || echo "--disable-locales")
+}
+
+src_install() {
+	distutils-r1_src_install --disable-autoupdate --skip-build \
+		$(use nls || echo "--disable-locales")
+
+	doicon picard.ico
+	domenu picard.desktop
+
+	local DOC_CONTENTS="If you are upgrading Picard and it does not start,
+try removing Picard's settings:
+	rm ~/.config/MusicBrainz/Picard.conf
+
+You should set the environment variable BROWSER to something like
+	firefox '%s' &
+to let python know which browser to use."
+	readme.gentoo_create_doc
+}
-- 
cgit v1.2.3