From 6bc2e4d7c5906e46a8f275a876ead6ec41aca5bb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 10 Feb 2019 15:40:27 +0000
Subject: gentoo resync : 10.02.2019

---
 media-sound/mpc/mpc-0.31-r1.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 media-sound/mpc/mpc-0.31-r1.ebuild

(limited to 'media-sound/mpc/mpc-0.31-r1.ebuild')

diff --git a/media-sound/mpc/mpc-0.31-r1.ebuild b/media-sound/mpc/mpc-0.31-r1.ebuild
new file mode 100644
index 000000000000..63e630daea44
--- /dev/null
+++ b/media-sound/mpc/mpc-0.31-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 meson
+
+DESCRIPTION="Commandline client for Music Player Daemon (media-sound/mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/mpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc iconv test"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+	iconv? ( virtual/libiconv )
+	test? ( dev-libs/check )
+"
+DEPEND="media-libs/libmpdclient"
+RDEPEND="${DEPEND}"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}/${P}-nodoc.patch" )
+
+src_prepare() {
+	default
+
+	# use correct docdir
+	sed -e "/install_dir:.*contrib/s/meson.project_name()/'${PF}'/" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Diconv=$(usex iconv enabled disabled)
+		-Dtest=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	newbashcomp contrib/mpc-completion.bash mpc
+}
-- 
cgit v1.2.3