From f3b17e517082e3c6581428440a122f1a2679e278 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Jul 2018 19:06:58 +0100
Subject: gentoo resync : 21.07.2018

---
 media-sound/grip/grip-3.9.0.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 media-sound/grip/grip-3.9.0.ebuild

(limited to 'media-sound/grip/grip-3.9.0.ebuild')

diff --git a/media-sound/grip/grip-3.9.0.ebuild b/media-sound/grip/grip-3.9.0.ebuild
new file mode 100644
index 000000000000..58adf1f69220
--- /dev/null
+++ b/media-sound/grip/grip-3.9.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic toolchain-funcs libtool
+
+DESCRIPTION="GTK+ based Audio CD Player/Ripper"
+HOMEPAGE="https://sourceforge.net/projects/grip/"
+SRC_URI="mirror://sourceforge/grip/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="vorbis"
+
+# lame and vorbis-tools are no real RDEPENDs. But without them
+# grip cannot convert ripped files to any format. So use them as
+# a sane default.
+RDEPEND="
+	gnome-base/libgnome
+	>=gnome-base/libgnomeui-2.2.0
+	>=media-libs/id3lib-3.8.3
+	media-sound/cdparanoia
+	media-sound/lame
+	net-misc/curl
+	>=x11-libs/gtk+-2.2:2
+	x11-libs/libX11
+	x11-libs/pango
+	x11-libs/vte:0
+	vorbis? ( media-sound/vorbis-tools )
+"
+# gnome-extra/yelp, see bug 416843
+DEPEND="
+	${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	sed '/^Icon/s@grip\b@gripicon@' -i grip.desktop || die
+}
+
+src_configure() {
+	# Bug #69536
+	[[ $(tc-arch) == "x86" ]] && append-flags "-mno-sse"
+
+	strip-linguas be bg ca de en en_CA en_GB en_US es fi fr hu it ja nb nl pl_PL pt_BR ru sr vi zh_CN zh_HK zh_TW
+
+	econf
+}
-- 
cgit v1.2.3