From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild | 56 ++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild

(limited to 'media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild')

diff --git a/media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild b/media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild
new file mode 100644
index 000000000000..7738a213805d
--- /dev/null
+++ b/media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="de en"
+inherit l10n toolchain-funcs
+
+DESCRIPTION="Nintendo Gameboy sound player for GBS format"
+HOMEPAGE="https://www.cgarbs.de/gbsplay.en.html"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+alsa nas nls oss"
+
+RDEPEND="alsa? ( media-libs/alsa-lib:0 )
+	nas? ( media-libs/nas:0 )"
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext:0 )"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-buildsystem.patch"
+)
+
+src_configure() {
+	tc-export AR CC
+
+	# No econf, because "unknown option '--build=x86_64-pc-linux-gnu'"
+	./configure \
+		--prefix=/usr \
+		--mandir=/usr/share/man \
+		--docdir=/usr/share/doc/${PF} \
+		--without-xmmsplugin \
+		--without-test \
+		$(use_enable nls i18n) \
+		$(use_enable oss devdsp) \
+		$(use_enable alsa) \
+		$(use_enable nas) || die "Configure failed."
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" SPLINT="true"
+}
+
+remove_disabled_locale() {
+	rm -r "${D}"/usr/share/locale/$1 || die
+}
+
+src_install() {
+	default
+
+	l10n_for_each_disabled_locale_do remove_disabled_locale
+}
-- 
cgit v1.2.3