From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 media-sound/drumstick/drumstick-2.3.1.ebuild | 69 ++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 media-sound/drumstick/drumstick-2.3.1.ebuild

(limited to 'media-sound/drumstick/drumstick-2.3.1.ebuild')

diff --git a/media-sound/drumstick/drumstick-2.3.1.ebuild b/media-sound/drumstick/drumstick-2.3.1.ebuild
new file mode 100644
index 000000000000..8b2d865ce0f9
--- /dev/null
+++ b/media-sound/drumstick/drumstick-2.3.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Qt/C++ wrapper for ALSA sequencer"
+HOMEPAGE="https://drumstick.sourceforge.io/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fluidsynth network pulseaudio"
+
+BDEPEND="
+	dev-libs/libxslt
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	x11-misc/shared-mime-info
+	doc? (
+		app-doc/doxygen[dot]
+		app-text/docbook-xsl-stylesheets
+	)
+"
+DEPEND="
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-libs/alsa-lib
+	fluidsynth? ( media-sound/fluidsynth )
+	network? ( dev-qt/qtnetwork:5 )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS readme.md TODO )
+
+RESTRICT="test"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=OFF
+		-DUSE_DBUS=ON
+		-DUSE_FLUIDSYNTH=$(usex fluidsynth)
+		-DUSE_NETWORK=$(usex network)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DBUILD_DOCS=$(usex doc)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doxygen
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	cmake_src_install
+}
-- 
cgit v1.2.3