From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild | 74 +++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild

(limited to 'media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild')

diff --git a/media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild b/media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild
new file mode 100644
index 000000000000..87137657c10e
--- /dev/null
+++ b/media-sound/alsa-utils/alsa-utils-1.1.4-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils systemd udev
+
+DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/utils/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0.9"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="bat doc +libsamplerate +ncurses nls selinux"
+
+CDEPEND=">=media-libs/alsa-lib-${PV}
+	libsamplerate? ( media-libs/libsamplerate )
+	ncurses? ( >=sys-libs/ncurses-5.7-r7:0= )
+	bat? ( sci-libs/fftw:= )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-text/xmlto )"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-alsa )"
+
+src_configure() {
+	local myconf
+	use doc || myconf='--disable-xmlto'
+
+	# --disable-alsaconf because it doesn't work with sys-apps/kmod wrt #456214
+	econf \
+		--disable-maintainer-mode \
+		$(use_enable bat) \
+		$(use_enable libsamplerate alsaloop) \
+		$(use_enable nls) \
+		$(use_enable ncurses alsamixer) \
+		--disable-alsaconf \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)" \
+		--with-udev-rules-dir="${EPREFIX}/$(get_udevdir)"/rules.d \
+		--with-asound-state-dir="${EPREFIX}"/var/lib/alsa \
+		${myconf}
+}
+
+src_install() {
+	default
+	dodoc seq/*/README.*
+
+	newinitd "${FILESDIR}"/alsasound.initd-r7 alsasound
+	newconfd "${FILESDIR}"/alsasound.confd-r4 alsasound
+
+	insinto /etc/modprobe.d
+	newins "${FILESDIR}"/alsa-modules.conf-rc alsa.conf
+
+	keepdir /var/lib/alsa
+
+	# ALSA lib parser.c:1266:(uc_mgr_scan_master_configs) error: could not
+	# scan directory /usr/share/alsa/ucm: No such file or directory
+	# alsaucm: unable to obtain card list: No such file or directory
+	keepdir /usr/share/alsa/ucm
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "To take advantage of the init script, and automate the process of"
+		elog "saving and restoring sound-card mixer levels you should"
+		elog "add alsasound to the boot runlevel. You can do this as"
+		elog "root like so:"
+		elog "# rc-update add alsasound boot"
+		ewarn
+		ewarn "The ALSA core should be built into the kernel or loaded through other"
+		ewarn "means. There is no longer any modular auto(un)loading in alsa-utils."
+	fi
+}
-- 
cgit v1.2.3