From 6ec19c7f1bc4aa70e5f8a86cd29d579a95d97035 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 18 Jan 2020 18:58:09 +0000
Subject: gentoo resync : 18.01.2020

---
 media-sound/abcm2ps/abcm2ps-8.14.6.ebuild | 49 +++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 media-sound/abcm2ps/abcm2ps-8.14.6.ebuild

(limited to 'media-sound/abcm2ps/abcm2ps-8.14.6.ebuild')

diff --git a/media-sound/abcm2ps/abcm2ps-8.14.6.ebuild b/media-sound/abcm2ps/abcm2ps-8.14.6.ebuild
new file mode 100644
index 000000000000..db152444cf7d
--- /dev/null
+++ b/media-sound/abcm2ps/abcm2ps-8.14.6.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Program to convert abc files to Postscript files"
+HOMEPAGE="https://github.com/leesavide/abcm2ps"
+SRC_URI="https://github.com/leesavide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="examples pango"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	pango? (
+		media-libs/freetype:2
+		x11-libs/pango
+	)"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	econf \
+		--enable-a4 \
+		--enable-deco-is-roll \
+		$(use_enable pango)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	dobin abcm2ps
+
+	insinto /usr/share/${PN}
+	doins *.fmt
+
+	dodoc README.md
+
+	if use examples ; then
+		docinto examples
+		dodoc sample*.*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3