From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-sound/aacgain/aacgain-1.9.ebuild | 100 +++++++++++++++++++++++++++++++++
 1 file changed, 100 insertions(+)
 create mode 100644 media-sound/aacgain/aacgain-1.9.ebuild

(limited to 'media-sound/aacgain/aacgain-1.9.ebuild')

diff --git a/media-sound/aacgain/aacgain-1.9.ebuild b/media-sound/aacgain/aacgain-1.9.ebuild
new file mode 100644
index 000000000000..d48172721789
--- /dev/null
+++ b/media-sound/aacgain/aacgain-1.9.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=4
+
+inherit eutils autotools
+
+FAAD2_PV="2.7"
+MP4V2_PV="1.9.1"
+MP3GAIN_PV="1.5.2"
+
+DESCRIPTION="AACGain normalizes the volume of music files using the Replay Gain algorithm"
+HOMEPAGE="http://aacgain.altosdesign.com/"
+SRC_URI="http://sbriesen.de/gentoo/distfiles/${P}.tar.xz
+	https://mp4v2.googlecode.com/files/mp4v2-${MP4V2_PV}.tar.bz2
+	mirror://sourceforge/mp3gain/mp3gain-${MP3GAIN_PV//./_}-src.zip
+	mirror://sourceforge/faac/faad2-${FAAD2_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND=""
+
+DOCS="${PN}/README"
+
+src_unpack() {
+	mkdir -p "${S}"
+	for X in ${A}; do
+		case "${X}" in
+			mp3gain*)
+				mkdir -p "${S}/${X%%-*}"
+				cd "${S}/${X%%-*}"
+				unpack "${X}"
+				;;
+			*)
+				cd "${S}"
+				unpack "${X}"
+				[ -d "${X%%-*}" ] || mv -f "${X%%-*}"-* "${X%%-*}"
+				;;
+		esac
+	done
+}
+
+src_prepare() {
+	sed -i -e 's:iquote :I:' faad2/libfaad/Makefile.am
+	sed -i -e 's:../\(mp4v2/\):\1:g' ${PN}/mp4v2.patch
+	sed -i -e 's:\(libmp4v2\|libfaad/libfaad\)\.la:README:g' \
+		-e 's:^\(autoreconf\|pushd\|popd\):# \1:g' aacgain/linux/prepare.sh
+
+	epatch ${PN}/mp4v2.patch
+	epatch "${FILESDIR}"/${P}-patch-dotdot.patch
+
+	cd "${S}/${PN}/linux"
+	sh prepare.sh || die "prepare failed!"
+
+	cd "${S}"
+	eautoreconf
+
+	cd "${S}/faad2"
+	eautoreconf
+
+	cd "${S}/mp4v2"
+	elibtoolize
+}
+
+src_configure() {
+	local myconf="--disable-dependency-tracking"
+	local myconf2="${myconf} --disable-shared --enable-static"
+
+	cd "${S}/faad2"
+	econf ${myconf2} --without-xmms --without-mpeg4ip
+
+	cd "${S}/mp4v2"
+	econf ${myconf2} --disable-gch
+
+	cd "${S}"
+	econf ${myconf}
+}
+
+src_compile() {
+	cd "${S}/faad2/libfaad"
+	emake
+
+	cd "${S}/mp4v2"
+	emake
+
+	cd "${S}"
+	emake
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "BACK UP YOUR MUSIC FILES BEFORE USING AACGAIN!"
+	ewarn "THIS IS EXPERIMENTAL SOFTWARE. THERE HAVE BEEN"
+	ewarn "BUGS IN PAST RELEASES THAT CORRUPTED MUSIC FILES."
+	ewarn
+}
-- 
cgit v1.2.3