From f1af93971b7490792d8541bc790e0d8c6d787059 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 6 Sep 2019 10:28:05 +0100
Subject: gentoo resync : 06.08.2019

---
 .../gst-plugins-opus-1.14.5.ebuild                 | 44 ++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 media-plugins/gst-plugins-opus/gst-plugins-opus-1.14.5.ebuild

(limited to 'media-plugins/gst-plugins-opus/gst-plugins-opus-1.14.5.ebuild')

diff --git a/media-plugins/gst-plugins-opus/gst-plugins-opus-1.14.5.ebuild b/media-plugins/gst-plugins-opus/gst-plugins-opus-1.14.5.ebuild
new file mode 100644
index 000000000000..070d047fd926
--- /dev/null
+++ b/media-plugins/gst-plugins-opus/gst-plugins-opus-1.14.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE=gst-plugins-base
+
+inherit gstreamer
+
+DESCRIPTION="Opus audio parser plugin for GStreamer"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+IUSE=""
+
+COMMON_DEPEND=">=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]"
+
+RDEPEND="${COMMON_DEPEND}
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP},ogg]
+"
+DEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+	default
+	gstreamer_system_link \
+		gst-libs/gst/tag:gstreamer-tag \
+		gst-libs/gst/pbutils:gstreamer-pbutils \
+		gst-libs/gst/audio:gstreamer-audio
+}
+
+# Everything below is for building opusparse from gst-plugins-bad. Once it moves into -base, all below can be removed
+SRC_URI+=" https://gstreamer.freedesktop.org/src/gst-plugins-bad/gst-plugins-bad-${PV}.tar.${GST_TARBALL_SUFFIX}"
+
+src_configure() {
+	multilib-minimal_src_configure
+	S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_configure
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+	S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_compile
+}
+
+src_install() {
+	multilib-minimal_src_install
+	S="${WORKDIR}/gst-plugins-bad-${PV}" multilib-minimal_src_install
+}
-- 
cgit v1.2.3