From fe8b106bd60ab72e98ab836f5c702070805e197e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 14 Oct 2022 07:43:49 +0100
Subject: gentoo auto-resync : 14:10:2022 - 07:43:49

---
 media-libs/tremor/tremor-0_pre20130223-r3.ebuild | 41 ++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 media-libs/tremor/tremor-0_pre20130223-r3.ebuild

(limited to 'media-libs/tremor/tremor-0_pre20130223-r3.ebuild')

diff --git a/media-libs/tremor/tremor-0_pre20130223-r3.ebuild b/media-libs/tremor/tremor-0_pre20130223-r3.ebuild
new file mode 100644
index 000000000000..2b454838d599
--- /dev/null
+++ b/media-libs/tremor/tremor-0_pre20130223-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A fixed-point version of the Ogg Vorbis decoder (also known as libvorbisidec)"
+HOMEPAGE="https://wiki.xiph.org/Tremor"
+SRC_URI="https://dev.gentoo.org/~ssuominen/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="low-accuracy"
+
+RDEPEND=">=media-libs/libogg-1.3.0:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-out-of-bounds-write.patch
+	"${FILESDIR}"/${P}-autoconf.patch
+	"${FILESDIR}"/${P}-pkgconfig.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf $(use_enable low-accuracy)
+}
+
+multilib_src_install_all() {
+	HTML_DOCS=( doc/. )
+	einstalldocs
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3