From 8b4ace9c50842c5b83401ea7b179dcab940387e1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 23 Sep 2020 10:22:15 +0100
Subject: gentoo resync : 23.09.2020

---
 media-libs/rubberband/rubberband-1.9.0.ebuild | 66 +++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 media-libs/rubberband/rubberband-1.9.0.ebuild

(limited to 'media-libs/rubberband/rubberband-1.9.0.ebuild')

diff --git a/media-libs/rubberband/rubberband-1.9.0.ebuild b/media-libs/rubberband/rubberband-1.9.0.ebuild
new file mode 100644
index 000000000000..97b291d58908
--- /dev/null
+++ b/media-libs/rubberband/rubberband-1.9.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="An audio time-stretching and pitch-shifting library and utility program"
+HOMEPAGE="https://www.breakfastquay.com/rubberband/"
+SRC_URI="https://breakfastquay.com/files/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ladspa static-libs +programs vamp"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+CDEPEND="
+	media-libs/libsamplerate[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	sci-libs/fftw:3.0[${MULTILIB_USEDEP}]
+	ladspa? ( media-libs/ladspa-sdk )
+	vamp? ( media-libs/vamp-plugin-sdk[${MULTILIB_USEDEP}] )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="${CDEPEND}"
+
+src_prepare() {
+	default
+	if ! use static-libs ; then
+		sed -e '/^all:/s/$(STATIC_TARGET)//' \
+			-e '/^\tcp $(STATIC_TARGET)/d' \
+			-i Makefile.in || die
+	fi
+
+	sed -e '/cp -f.*JNI_TARGET/d' -i Makefile.in || die
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable programs ) \
+		$(use_enable ladspa ) \
+		$(use_enable vamp )
+}
+
+multilib_src_install() {
+	# fix libdir in .pc file
+	sed -iE "s%/lib$%/$(get_libdir)%g" "${BUILD_DIR}/rubberband.pc.in" || die "Failed to fix .pc file"
+
+	emake INSTALL_BINDIR="${ED}/usr/bin" \
+		INSTALL_INCDIR="${ED}/usr/include/rubberband" \
+		INSTALL_LIBDIR="${ED}/usr/$(get_libdir)" \
+		INSTALL_VAMPDIR="${ED}/usr/$(get_libdir)/vamp" \
+		INSTALL_LADSPADIR="${ED}/usr/$(get_libdir)/ladspa" \
+		INSTALL_LRDFDIR="${ED}/usr/share/ladspa/rdf" \
+		INSTALL_PKGDIR="${ED}/usr/$(get_libdir)/pkgconfig" \
+		install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+}
-- 
cgit v1.2.3