From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 media-libs/rtaudio/rtaudio-5.0.0.ebuild | 62 +++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 media-libs/rtaudio/rtaudio-5.0.0.ebuild

(limited to 'media-libs/rtaudio/rtaudio-5.0.0.ebuild')

diff --git a/media-libs/rtaudio/rtaudio-5.0.0.ebuild b/media-libs/rtaudio/rtaudio-5.0.0.ebuild
new file mode 100644
index 000000000000..e518d5d6b8bb
--- /dev/null
+++ b/media-libs/rtaudio/rtaudio-5.0.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit ltprune autotools
+
+DESCRIPTION="A set of cross-platform C++ classes for realtime audio I/O"
+HOMEPAGE="https://www.music.mcgill.ca/~gary/rtaudio/"
+SRC_URI="https://www.music.mcgill.ca/~gary/${PN}/release/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/6"
+KEYWORDS="~amd64 ~x86"
+IUSE="+alsa doc jack pulseaudio static-libs"
+REQUIRED_USE="|| ( alsa jack pulseaudio )"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? (
+		media-libs/alsa-lib
+		media-sound/jack-audio-connection-kit
+	)
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.1.2-cflags.patch
+)
+
+src_prepare() {
+	default
+
+	# don't rebuild docs
+	export ac_cv_prog_DOXYGEN=
+
+	eautoreconf
+}
+
+src_configure() {
+	# OSS support requires OSSv4
+	local myconf=(
+		$(use_enable static-libs static)
+		$(use_with jack)
+		$(use_with alsa)
+		$(use_with pulseaudio pulse)
+		--without-oss
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc readme doc/release.txt
+	if use doc; then
+		dodoc -r doc/html
+		dodoc -r doc/images
+	fi
+
+	prune_libtool_files
+}
-- 
cgit v1.2.3