From 249ae8c1a241b514fc83737660927ee175091346 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 27 Dec 2023 19:39:54 +0000
Subject: gentoo auto-resync : 27:12:2023 - 19:39:54

---
 media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild | 88 ++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild

(limited to 'media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild')

diff --git a/media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild b/media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild
new file mode 100644
index 000000000000..020b5fd8f482
--- /dev/null
+++ b/media-libs/lsp-plugins/lsp-plugins-1.2.14.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2019-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic xdg
+
+DESCRIPTION="Linux Studio Plugins"
+HOMEPAGE="https://lsp-plug.in"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lsp-plugins/lsp-plugins"
+	EGIT_BRANCH="devel"
+else
+	SRC_URI="https://github.com/lsp-plugins/${PN}/releases/download/${PV}/${PN}-src-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="doc jack ladspa +lv2 test vst X"
+REQUIRED_USE="|| ( jack ladspa lv2 )
+	test? ( jack )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( dev-lang/php:* )"
+DEPEND="
+	media-libs/libglvnd[X]
+	media-libs/libsndfile
+	jack? (
+		media-libs/freetype
+		virtual/jack
+		x11-libs/cairo[X]
+		x11-libs/libX11
+		x11-libs/libXrandr
+	)
+	ladspa? ( media-libs/ladspa-sdk )
+	lv2? (
+		media-libs/freetype
+		media-libs/lv2
+		x11-libs/cairo[X]
+		x11-libs/libX11
+		x11-libs/libXrandr
+	)
+	vst? (
+		media-libs/freetype
+		x11-libs/cairo[X]
+		x11-libs/libX11
+		x11-libs/libXrandr
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	use doc && MODULES+="doc"
+	use jack && MODULES+=" jack"
+	use ladspa && MODULES+=" ladspa"
+	use lv2 && MODULES+=" lv2"
+	use vst && MODULES+=" vst2"
+	use X && MODULES+=" xdg"
+	emake \
+		FEATURES="${MODULES}" \
+		PREFIX="/usr" \
+		LIBDIR="/usr/$(get_libdir)" \
+		CFLAGS_EXT="${CFLAGS}" \
+		CXXFLAGS_EXT="${CXXFLAGS}" \
+		LDFLAGS_EXT="$(raw-ldflags)" \
+		VERBOSE=1 \
+		config
+}
+
+src_compile() {
+	emake \
+		FEATURES="${MODULES}" \
+		PREFIX="/usr" \
+		LIBDIR="/usr/$(get_libdir)" \
+		CFLAGS_EXT="${CFLAGS}" \
+		CXXFLAGS_EXT="${CXXFLAGS}" \
+		LDFLAGS_EXT="$(raw-ldflags)" \
+		VERBOSE=1
+}
+
+src_install() {
+	emake PREFIX="/usr" DESTDIR="${ED}" LIB_PATH="/usr/$(get_libdir)" VERBOSE=1 install
+}
-- 
cgit v1.2.3