From 1fd4e372381e1318aae1b7d3338c04156e5da974 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 16 Jul 2022 19:46:11 +0100
Subject: gentoo auto-resync : 16:07:2022 - 19:46:10

---
 media-libs/libwebp/libwebp-1.2.3.ebuild | 76 +++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 media-libs/libwebp/libwebp-1.2.3.ebuild

(limited to 'media-libs/libwebp/libwebp-1.2.3.ebuild')

diff --git a/media-libs/libwebp/libwebp-1.2.3.ebuild b/media-libs/libwebp/libwebp-1.2.3.ebuild
new file mode 100644
index 000000000000..32347bc9d186
--- /dev/null
+++ b/media-libs/libwebp/libwebp-1.2.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools multilib-minimal
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="A lossy image compression format"
+HOMEPAGE="https://developers.google.com/speed/webp/download"
+SRC_URI="https://storage.googleapis.com/downloads.webmproject.org/releases/webp/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/7" # subslot = libwebp soname version
+[[ ${PV} = *_rc* ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="cpu_flags_arm_neon cpu_flags_x86_sse2 cpu_flags_x86_sse4_1 gif +jpeg opengl +png static-libs swap-16bit-csp tiff"
+
+# TODO: dev-lang/swig bindings in swig/ subdirectory
+RDEPEND="gif? ( media-libs/giflib:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	opengl? (
+		media-libs/freeglut
+		virtual/opengl
+	)
+	png? ( media-libs/libpng:= )
+	tiff? ( media-libs/tiff:= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.2.3-libpng-pkg-config.patch
+)
+
+src_prepare() {
+	default
+
+	# Fix libtool relinking, bug #499270.
+	#elibtoolize
+
+	# Needed for pkg-config patch
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local args=(
+		--enable-libwebpmux
+		--enable-libwebpdemux
+		--enable-libwebpdecoder
+		$(use_enable static-libs static)
+		$(use_enable swap-16bit-csp)
+		$(use_enable jpeg)
+		$(use_enable png)
+		$(use_enable opengl gl)
+		$(use_enable tiff)
+
+		$(use_enable cpu_flags_x86_sse2 sse2)
+		$(use_enable cpu_flags_x86_sse4_1 sse4.1)
+		$(use_enable cpu_flags_arm_neon neon)
+
+		# Only used for gif2webp binary wrt bug #486646
+		$(multilib_native_use_enable gif)
+	)
+
+	ECONF_SOURCE="${S}" econf "${args[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name "*.la" -delete || die
+	dodoc AUTHORS ChangeLog doc/*.txt NEWS README.md
+}
-- 
cgit v1.2.3