From f8d2edf76d3901ebc1ace32c33a4d547fd5eee63 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 11 Sep 2023 04:37:21 +0100
Subject: gentoo auto-resync : 11:09:2023 - 04:37:21

---
 .../libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild  | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 media-libs/libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild

(limited to 'media-libs/libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild')

diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild
new file mode 100644
index 000000000000..dac5de3f03bb
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20221208-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic autotools
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+
+LIBTGVOIP_COMMIT="0ffe2e51bfe14b533b860002f1c2e87e5f8c00c0"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${LIBTGVOIP_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${LIBTGVOIP_COMMIT}"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~ppc64 ~riscv"
+IUSE="+dsp +alsa pulseaudio"
+
+DEPEND="
+	dev-libs/openssl:=
+	media-libs/opus
+	alsa? ( media-libs/alsa-lib )
+	dsp? ( media-libs/tg_owt:= )
+	pulseaudio? ( media-libs/libpulse )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+REQUIRED_USE="
+	|| ( alsa pulseaudio )
+"
+
+src_prepare() {
+	# Will be controlled by us
+	sed -i -e '/^CFLAGS += -DTGVOIP_NO_DSP/d' Makefile.am || die
+	# https://bugs.gentoo.org/717210
+	echo 'libtgvoip_la_LIBTOOLFLAGS = --tag=CXX' >> Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Not using the CMake build despite being the preferred one, because
+	# it's lacking relevant configure options.
+	local myconf=(
+		--disable-dsp  # WebRTC is linked from tg_owt
+		$(use_with alsa)
+		$(use_with pulseaudio pulse)
+	)
+	if use dsp; then
+		append-cppflags "-I${ESYSROOT}/usr/include/tg_owt"
+		append-cppflags "-I${ESYSROOT}/usr/include/tg_owt/third_party/abseil-cpp"
+		append-libs '-ltg_owt'
+	else
+		append-cppflags '-DTGVOIP_NO_DSP'
+	fi
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3