From f29eb0598f62fc3b5f09f2de5a89c0437c6164d9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 21 Jan 2020 18:52:40 +0000
Subject: gentoo resync : 21.01.2020

---
 .../libprojectm/libprojectm-3.1.1_rc8.ebuild       | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 media-libs/libprojectm/libprojectm-3.1.1_rc8.ebuild

(limited to 'media-libs/libprojectm/libprojectm-3.1.1_rc8.ebuild')

diff --git a/media-libs/libprojectm/libprojectm-3.1.1_rc8.ebuild b/media-libs/libprojectm/libprojectm-3.1.1_rc8.ebuild
new file mode 100644
index 000000000000..b92df75eef3f
--- /dev/null
+++ b/media-libs/libprojectm/libprojectm-3.1.1_rc8.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A graphical music visualization plugin similar to milkdrop"
+HOMEPAGE="https://github.com/projectM-visualizer/projectm"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/projectM-visualizer/projectm.git"
+	inherit git-r3
+else
+	MY_PV="${PV/_/-}"
+	SRC_URI="https://github.com/projectM-visualizer/projectm/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~sparc ~x86"
+	S=${WORKDIR}/projectm-${MY_PV}/
+fi
+
+LICENSE="LGPL-2"
+SLOT="0/2"
+IUSE="gles2 qt5 sdl"
+
+RDEPEND="gles2? ( media-libs/mesa[gles2] )
+	media-libs/glm
+	media-libs/mesa[X(+)]
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtopengl:5
+		media-sound/pulseaudio
+	)
+	sdl? ( >=media-libs/libsdl2-2.0.5 )
+	sys-libs/zlib"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable gles2 gles)
+		$(use_enable qt5 qt)
+		$(use_enable sdl)
+		--enable-emscripten=no
+	)
+	econf "${myeconfargs[@]}"
+}
-- 
cgit v1.2.3