From 840a65e2af3f2cc7527e723a28f6e627a9592fb7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 30 Jan 2024 11:49:23 +0000
Subject: gentoo auto-resync : 30:01:2024 - 11:49:23

---
 media-libs/libpng/libpng-1.6.41-r1.ebuild | 74 +++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 media-libs/libpng/libpng-1.6.41-r1.ebuild

(limited to 'media-libs/libpng/libpng-1.6.41-r1.ebuild')

diff --git a/media-libs/libpng/libpng-1.6.41-r1.ebuild b/media-libs/libpng/libpng-1.6.41-r1.ebuild
new file mode 100644
index 000000000000..e82599595cdf
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.41-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool multilib-minimal
+
+APNG_REPO=libpng-apng # sometimes libpng-apng is more up to date
+APNG_VERSION="1.6.40"
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? (
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PV}/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
+	)
+"
+
+LICENSE="libpng2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-png_check_sig-abi.patch
+)
+
+src_prepare() {
+	default
+
+	if use apng; then
+		case ${APNG_REPO} in
+			apng)
+				eapply -p0 "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
+				;;
+			libpng-apng)
+				eapply "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
+				;;
+			*)
+				die "Unknown APNG_REPO!"
+				;;
+		esac
+
+		# Don't execute symbols check with apng patch, bug #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(multilib_native_enable tools)
+		$(use_enable test tests)
+		$(use_enable cpu_flags_arm_neon arm-neon)
+		$(use_enable cpu_flags_x86_sse intel-sse)
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+
+	find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
+}
-- 
cgit v1.2.3