From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 media-libs/libpng/libpng-1.6.37-r2.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 media-libs/libpng/libpng-1.6.37-r2.ebuild

(limited to 'media-libs/libpng/libpng-1.6.37-r2.ebuild')

diff --git a/media-libs/libpng/libpng-1.6.37-r2.ebuild b/media-libs/libpng/libpng-1.6.37-r2.ebuild
new file mode 100644
index 000000000000..5ac038821903
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.37-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
+
+LICENSE="libpng2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if use apng; then
+		eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable cpu_flags_x86_sse intel-sse)
+		$(use_enable static-libs static)
+		--enable-arm-neon=$(usex cpu_flags_arm_neon)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+	einstalldocs
+	find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
+}
-- 
cgit v1.2.3