From 4eeee822487f780361d7d47b4c1b999f93e15b27 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 18 Sep 2023 23:07:14 +0100
Subject: gentoo auto-resync : 18:09:2023 - 23:07:14

---
 media-libs/libpano13/libpano13-2.9.22.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 media-libs/libpano13/libpano13-2.9.22.ebuild

(limited to 'media-libs/libpano13/libpano13-2.9.22.ebuild')

diff --git a/media-libs/libpano13/libpano13-2.9.22.ebuild b/media-libs/libpano13/libpano13-2.9.22.ebuild
new file mode 100644
index 000000000000..11f4bcc72a58
--- /dev/null
+++ b/media-libs/libpano13/libpano13-2.9.22.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit java-pkg-opt-2 cmake
+
+DESCRIPTION="Helmut Dersch's panorama toolbox library"
+HOMEPAGE="http://panotools.sourceforge.net/"
+SRC_URI="mirror://sourceforge/panotools/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="java static-libs suitesparse"
+
+DEPEND="media-libs/libpng:=
+	media-libs/tiff:=
+	media-libs/libjpeg-turbo:=
+	sys-libs/zlib
+	java? ( >=virtual/jdk-1.8:* )
+	suitesparse? ( sci-libs/suitesparse )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-$(ver_cut 1-3)"
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSUPPORT_JAVA_PROGRAMS=$(usex java)
+		-DUSE_SPARSE_LEVMAR=$(usex suitesparse)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if ! use static-libs ; then
+		find "${D}" -name "*.a" -type f -delete || die
+	fi
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}
-- 
cgit v1.2.3