From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild

(limited to 'media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild')

diff --git a/media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild b/media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild
new file mode 100644
index 000000000000..84aea87a2a3f
--- /dev/null
+++ b/media-libs/libopenaptx/libopenaptx-0.2.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic multilib-minimal toolchain-funcs
+
+DESCRIPTION="Reverse-engineered aptX and aptX HD library"
+HOMEPAGE="https://github.com/pali/libopenaptx"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pali/${PN}"
+else
+	SRC_URI="https://github.com/pali/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+IUSE="cpu_flags_x86_avx2"
+
+src_prepare() {
+	default
+
+	# custom Makefiles
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	tc-export CC AR
+
+	use cpu_flags_x86_avx2 && append-cflags "-mavx2"
+
+	emake \
+		PREFIX="${EPREFIX}"/usr \
+		LIBDIR=$(get_libdir) \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		ARFLAGS="${ARFLAGS} -rcs" \
+		all
+}
+
+multilib_src_install() {
+	emake \
+		PREFIX="${EPREFIX}"/usr \
+		DESTDIR="${D}" \
+		LIBDIR="$(get_libdir)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		ARFLAGS="${ARFLAGS} -rcs" \
+		install
+
+	rm -f "${ED}/usr/$(get_libdir)"/libopenaptx.a || die "Failed to remove static lib"
+}
-- 
cgit v1.2.3