From ed8299fef4175104e66b734cfc0482770614f398 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 23 Dec 2023 13:50:55 +0000
Subject: gentoo auto-resync : 23:12:2023 - 13:50:55

---
 media-libs/libmpdclient/libmpdclient-2.22.ebuild | 43 ++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 media-libs/libmpdclient/libmpdclient-2.22.ebuild

(limited to 'media-libs/libmpdclient/libmpdclient-2.22.ebuild')

diff --git a/media-libs/libmpdclient/libmpdclient-2.22.ebuild b/media-libs/libmpdclient/libmpdclient-2.22.ebuild
new file mode 100644
index 000000000000..71bef1dc1eb1
--- /dev/null
+++ b/media-libs/libmpdclient/libmpdclient-2.22.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Library for interfacing Music Player Daemon (media-sound/mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/libmpdclient"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="test? ( dev-libs/check )"
+
+src_prepare() {
+	default
+
+	sed -e "s:@top_srcdir@:.:" -i doc/doxygen.conf.in || die
+
+	# meson doesn't support setting docdir
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "/^install_data(/s/'COPYING', //" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc true false)
+		-Dtest=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	use examples && dodoc src/example.c
+}
-- 
cgit v1.2.3