From 3f71901f8c228f4de570abed1831ce3ee425343e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 8 Sep 2018 10:50:14 +0100
Subject: gentoo resync 08.09.2018

---
 media-libs/libmpdclient/libmpdclient-2.14.ebuild | 47 ++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 media-libs/libmpdclient/libmpdclient-2.14.ebuild

(limited to 'media-libs/libmpdclient/libmpdclient-2.14.ebuild')

diff --git a/media-libs/libmpdclient/libmpdclient-2.14.ebuild b/media-libs/libmpdclient/libmpdclient-2.14.ebuild
new file mode 100644
index 000000000000..70d69fc459da
--- /dev/null
+++ b/media-libs/libmpdclient/libmpdclient-2.14.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit meson
+
+DESCRIPTION="A library for interfacing Music Player Daemon (media-sound/mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/libmpdclient"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=""
+DEPEND="
+	doc? ( app-doc/doxygen )
+	test? ( dev-libs/check )
+"
+
+src_prepare() {
+	default
+
+	sed -i "s:@top_srcdir@:.:" doc/doxygen.conf.in || die
+
+	# meson doesn't support setting docdir
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "/^install_data(/s/'COPYING', //" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc true false)
+		-Dtest=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	use examples && dodoc src/example.c
+	use doc || rm -rf "${ED}"/usr/share/doc/${PF}/html
+}
-- 
cgit v1.2.3