From 7405d8a728a9553d7b8eccb67737c5193c9f13ba Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 24 Aug 2022 08:47:16 +0100
Subject: gentoo auto-resync : 24:08:2022 - 08:47:15

---
 media-libs/libglvnd/libglvnd-1.5.0.ebuild | 65 +++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 media-libs/libglvnd/libglvnd-1.5.0.ebuild

(limited to 'media-libs/libglvnd/libglvnd-1.5.0.ebuild')

diff --git a/media-libs/libglvnd/libglvnd-1.5.0.ebuild b/media-libs/libglvnd/libglvnd-1.5.0.ebuild
new file mode 100644
index 000000000000..8fc4e707e6ae
--- /dev/null
+++ b/media-libs/libglvnd/libglvnd-1.5.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2018-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+EGIT_REPO_URI="https://gitlab.freedesktop.org/glvnd/libglvnd.git"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{8..11} )
+VIRTUALX_REQUIRED=manual
+
+inherit ${GIT_ECLASS} meson-multilib python-any-r1 virtualx
+
+DESCRIPTION="The GL Vendor-Neutral Dispatch library"
+HOMEPAGE="https://gitlab.freedesktop.org/glvnd/libglvnd"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+	SRC_URI="https://gitlab.freedesktop.org/glvnd/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
+	S=${WORKDIR}/${PN}-v${PV}
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test X"
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )"
+RDEPEND="
+	!media-libs/mesa[-libglvnd(+)]
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+
+src_prepare() {
+	default
+	sed -i -e "/^PLATFORM_SYMBOLS/a '__gentoo_check_ldflags__'," \
+		bin/symbols-check.py || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature X x11)
+		$(meson_feature X glx)
+	)
+	use elibc_musl && emesonargs+=( -Dtls=false )
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	if use X; then
+		virtx meson_src_test
+	else
+		meson_src_test
+	fi
+}
-- 
cgit v1.2.3