From 5b36c18aaba339882ed70281371a1059d9e7943f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 12 Apr 2023 17:41:40 +0100
Subject: gentoo auto-resync : 12:04:2023 - 17:41:40

---
 media-libs/jasper/jasper-4.0.0.ebuild | 56 +++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 media-libs/jasper/jasper-4.0.0.ebuild

(limited to 'media-libs/jasper/jasper-4.0.0.ebuild')

diff --git a/media-libs/jasper/jasper-4.0.0.ebuild b/media-libs/jasper/jasper-4.0.0.ebuild
new file mode 100644
index 000000000000..3ebc6a27c799
--- /dev/null
+++ b/media-libs/jasper/jasper-4.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Implementation of the codec specified in the JPEG-2000 Part-1 standard"
+HOMEPAGE="https://jasper-software.github.io/jasper"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jasper-software/jasper.git"
+else
+	SRC_URI="https://github.com/jasper-software/${PN}/archive/version-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${PN}-version-${PV}"
+fi
+
+LICENSE="JasPer2.0"
+SLOT="0/7"
+IUSE="doc heif jpeg opengl"
+
+RDEPEND="
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	opengl? (
+		media-libs/freeglut
+		virtual/opengl
+		virtual/glu
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-shells/bash
+	doc? ( app-doc/doxygen )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBASH_PROGRAM="${BROOT}"/bin/bash
+
+		# documentation
+		$(cmake_use_find_package doc Doxygen)
+		$(cmake_use_find_package doc LATEX)
+
+		# HEIF
+		-DJAS_ENABLE_LIBHEIF=$(usex heif)
+
+		# JPEG
+		-DJAS_ENABLE_LIBJPEG=$(usex jpeg)
+
+		# OpenGL
+		-DJAS_ENABLE_OPENGL=$(usex opengl)
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3