From 81b8f20732954c4508baf2f77472b5435e3f851f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 14 Sep 2022 11:10:11 +0100
Subject: gentoo auto-resync : 14:09:2022 - 11:10:10

---
 media-libs/flac/flac-1.4.0-r1.ebuild | 64 ++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 media-libs/flac/flac-1.4.0-r1.ebuild

(limited to 'media-libs/flac/flac-1.4.0-r1.ebuild')

diff --git a/media-libs/flac/flac-1.4.0-r1.ebuild b/media-libs/flac/flac-1.4.0-r1.ebuild
new file mode 100644
index 000000000000..04c10bfb50cb
--- /dev/null
+++ b/media-libs/flac/flac-1.4.0-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="Free lossless audio encoder and decoder"
+HOMEPAGE="https://xiph.org/flac/"
+SRC_URI="https://downloads.xiph.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
+# <libFLAC SONAME>-<libFLAC++ SONAME>
+SLOT="0/10-12"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cxx debug ogg cpu_flags_ppc_altivec cpu_flags_ppc_vsx cpu_flags_x86_avx2 cpu_flags_x86_avx cpu_flags_x86_sse static-libs"
+
+# AVX configure switch is for both AVX & AVX2
+REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+"
+
+RDEPEND="ogg? ( media-libs/libogg[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+	abi_x86_32? ( dev-lang/nasm )"
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-doxygen-docs
+		--disable-examples
+		--disable-xmms-plugin
+		$([[ ${CHOST} == *-darwin* ]] && echo "--disable-asm-optimizations")
+		$(use_enable cpu_flags_ppc_altivec altivec)
+		$(use_enable cpu_flags_ppc_vsx vsx)
+		$(use_enable cpu_flags_x86_avx avx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable cxx cpplibs)
+		$(use_enable debug)
+		$(use_enable ogg)
+		$(use_enable static-libs static)
+
+		# cross-compile fix (bug #521446)
+		# no effect if ogg support is disabled
+		--with-ogg
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	if [[ ${UID} != 0 ]]; then
+		emake -j1 check
+	else
+		ewarn "Tests will fail if ran as root, skipping."
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3