From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 media-libs/fcft/fcft-3.1.2-r1.ebuild | 94 ++++++++++++++++++++++++++++++++++++
 1 file changed, 94 insertions(+)
 create mode 100644 media-libs/fcft/fcft-3.1.2-r1.ebuild

(limited to 'media-libs/fcft/fcft-3.1.2-r1.ebuild')

diff --git a/media-libs/fcft/fcft-3.1.2-r1.ebuild b/media-libs/fcft/fcft-3.1.2-r1.ebuild
new file mode 100644
index 000000000000..9ecda1e5c4a3
--- /dev/null
+++ b/media-libs/fcft/fcft-3.1.2-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit meson python-any-r1
+
+DESCRIPTION="Simple library for font loading and glyph rasterization"
+HOMEPAGE="https://codeberg.org/dnkl/fcft"
+SRC_URI="https://codeberg.org/dnkl/fcft/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+# MIT for fcft
+# ZLIB for nanosvg
+LICENSE="MIT ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="examples +harfbuzz +libutf8proc test"
+REQUIRED_USE="
+	libutf8proc? ( harfbuzz )
+	examples? ( libutf8proc )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/pixman
+	examples? (
+		dev-libs/libutf8proc:=
+		dev-libs/wayland
+	)
+	harfbuzz? (
+		media-libs/harfbuzz:=[truetype]
+	)
+	libutf8proc? (
+		dev-libs/libutf8proc:=
+	)
+"
+DEPEND="
+	${RDEPEND}
+	app-i18n/unicode-data
+	dev-libs/tllist
+	examples? (
+		dev-libs/wayland-protocols
+	)
+	test? (
+		dev-libs/check
+		harfbuzz? ( media-fonts/noto-emoji )
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-text/scdoc
+	virtual/pkgconfig
+	examples? (
+		dev-util/wayland-scanner
+	)
+"
+
+src_prepare() {
+	default
+
+	rm -r unicode || die "Failed removing vendored unicode-data"
+
+	sed -i "s;unicode/UnicodeData.txt;${EPREFIX}/usr/share/unicode-data/UnicodeData.txt;" \
+		meson.build || die "Failed changing UnicodeData.txt to system's copy"
+	sed -i "s;unicode/emoji-data.txt;${EPREFIX}/usr/share/unicode-data/emoji/emoji-data.txt;" \
+		meson.build || die "Failed changing emoji-data.txt to system's copy"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature harfbuzz grapheme-shaping)
+		$(meson_feature libutf8proc run-shaping)
+		$(meson_use examples)
+		$(use test && meson_use harfbuzz test-text-shaping)
+		# bundled, tiny, I believe this means we should always include it
+		-Dsvg-backend=nanosvg
+		-Ddocs=enabled
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	local DOCS=( CHANGELOG.md README.md )
+	meson_src_install
+
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+
+	use examples && newbin "${BUILD_DIR}/example/example" fcft-example
+}
-- 
cgit v1.2.3