From f1317d9384e4b8cbbd93ff4ceb8bd87fa9d3a4f1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 17 Dec 2022 15:39:26 +0000
Subject: gentoo auto-resync : 17:12:2022 - 15:39:26

---
 media-libs/exempi/exempi-2.6.3.ebuild | 67 +++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 media-libs/exempi/exempi-2.6.3.ebuild

(limited to 'media-libs/exempi/exempi-2.6.3.ebuild')

diff --git a/media-libs/exempi/exempi-2.6.3.ebuild b/media-libs/exempi/exempi-2.6.3.ebuild
new file mode 100644
index 000000000000..a0ee85622c49
--- /dev/null
+++ b/media-libs/exempi/exempi-2.6.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Port of the Adobe XMP SDK to work on UNIX"
+HOMEPAGE="https://libopenraw.freedesktop.org/wiki/Exempi"
+SRC_URI="https://libopenraw.freedesktop.org/download/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="2/8"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/expat-2:=
+	sys-libs/zlib
+	virtual/libiconv
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-libs/boost )
+"
+BDEPEND="
+	sys-devel/autoconf-archive
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.2-iconv.patch
+)
+
+src_prepare() {
+	default
+
+	# Needed for autoconf 2.71
+	config_rpath_update .
+	eautoreconf
+}
+
+src_configure() {
+	# - --enable-static as --disable-static breaks build
+	# - Valgrind detection is "disabled" due to bug #295875
+	econf \
+		--enable-static \
+		$(use_enable test unittest) \
+		VALGRIND=""
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		emake -C samples/source distclean
+		rm samples/{,source,testfiles}/Makefile* || die
+		docinto examples
+		dodoc -r samples/.
+	fi
+
+	# --disable-static breaks tests
+	rm -rf "${ED}/usr/$(get_libdir)/libexempi.a" || die
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3