From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 media-libs/devil/Manifest              |  1 +
 media-libs/devil/devil-1.7.8-r3.ebuild | 91 ++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 media-libs/devil/devil-1.7.8-r3.ebuild

(limited to 'media-libs/devil')

diff --git a/media-libs/devil/Manifest b/media-libs/devil/Manifest
index 6bbe0969dd14..219c859f696e 100644
--- a/media-libs/devil/Manifest
+++ b/media-libs/devil/Manifest
@@ -7,4 +7,5 @@ AUX devil-1.7.8-nvtt-glut.patch 2493 BLAKE2B 4f96f75a6a49c1cdd4b3b89101be693ce4a
 AUX devil-1.7.8-restrict.patch 587 BLAKE2B 265496bb262c945812182764903497d3b4b851eb48980d32197a7d732337ded032272544f7aef1cd725a796093ed274bf38b43bb4138b3bf199de2601a9c5732 SHA512 9370a94406e98979266d027857d7dd04069eefb6e2ccfb52d254b9eb658d932e5e7e9bd3a38aad57099b870c54aaa0a2d8b337f9bad42d06f6521c10d0a6f8db
 DIST DevIL-1.7.8.tar.gz 2051993 BLAKE2B 7c06549f7d90965fe6dcd7c6b460119a8491ca50f3103c745195fa5483885878717e9ae417eda51f25cbb60c0a96be180b12727115212709199ded13156ecb3e SHA512 a67e1488d6cb366431d9fcb460b8fe5b8a1dd79426ac77f8abd0db4a5aad7512697f72ef0c49ddb0e806469cc37ba1319e10ccd2ebd73942332df2c3c507458e
 EBUILD devil-1.7.8-r2.ebuild 2142 BLAKE2B d9ef2e6223ea2de918726a6f73f6cb342aea5a092be8a2e0ead630bcf0ef31af3f6ef79ef043c0e9eca2b8701d9ce2462b801bb8405acc92f0c6aacfc1dab14a SHA512 0539a865a64ffc14e0afec959e28277c81bd83f1c4e31155bd43b24429000e983e839e71c8b8639b2145ee374d94ec2c0501b9752b9bb01483c87d5f910331e4
+EBUILD devil-1.7.8-r3.ebuild 2160 BLAKE2B 570703c1faf8fb03c0b112e36b7246cdbdfd3e7bdb6257c5e7470bfbb855b8871687e35455c0305127fe52a9c02ed4429eb2aab7cb65d3591d80935afe8f462d SHA512 91b32333c10c9dc2e35018660d1165b88e2a3d236806d8ccc4bc9cbfaf04295147aa993db6675fbf632123be4dac4d76005deb9a4d8267cb2a92b1b50c716b83
 MISC metadata.xml 500 BLAKE2B ea23c56af001f0fc76e8f5a1e718a7fe7f011139bed10081f9a1b220b82f43da353722fe3e6a80fa8de7162d7c55da109617df50f428a0b973ddf1bfe27158d5 SHA512 7902a135b51029e4cf8fe5f9baf5e38250d5e471d820b98b9440a0be72c90902694b89e8d32de1d8e595384642ade6a7435aeba85c928e6d3f4cacde72925dc6
diff --git a/media-libs/devil/devil-1.7.8-r3.ebuild b/media-libs/devil/devil-1.7.8-r3.ebuild
new file mode 100644
index 000000000000..113a199ada8a
--- /dev/null
+++ b/media-libs/devil/devil-1.7.8-r3.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_P=DevIL-${PV}
+
+DESCRIPTION="DevIL image library"
+HOMEPAGE="http://openil.sourceforge.net/"
+SRC_URI="mirror://sourceforge/openil/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~mips ppc ppc64 ~riscv x86"
+IUSE="allegro cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 gif glut jpeg mng nvtt opengl png sdl static-libs tiff X xpm"
+
+# OpenEXR support dropped b/c no support for OpenEXR 3
+# See bug #833833
+RDEPEND="
+	allegro? ( media-libs/allegro:0 )
+	gif? ( media-libs/giflib:= )
+	glut? ( media-libs/freeglut )
+	jpeg? ( virtual/jpeg:0 )
+	mng? ( media-libs/libmng:= )
+	nvtt? ( media-gfx/nvidia-texture-tools )
+	opengl? ( virtual/opengl
+		virtual/glu )
+	png? ( media-libs/libpng:0= )
+	sdl? ( media-libs/libsdl )
+	tiff? ( media-libs/tiff:0 )
+	X? ( x11-libs/libXext
+		x11-libs/libX11
+		x11-libs/libXrender )
+	xpm? ( x11-libs/libXpm )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	X? ( x11-base/xorg-proto )"
+
+PATCHES=(
+	"${FILESDIR}/${P}"-CVE-2009-3994.patch
+	"${FILESDIR}/${P}"-libpng14.patch
+	"${FILESDIR}/${P}"-nvtt-glut.patch
+	"${FILESDIR}/${P}"-ILUT.patch
+	"${FILESDIR}/${P}"-restrict.patch
+	"${FILESDIR}/${P}"-fix-test.patch
+	"${FILESDIR}/${P}"-jasper-remove-uchar.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--disable-lcms \
+		--enable-ILU \
+		--enable-ILUT \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable cpu_flags_x86_sse3 sse3) \
+		--disable-exr \
+		$(use_enable gif) \
+		$(use_enable jpeg) \
+		--enable-jp2 \
+		$(use_enable mng) \
+		$(use_enable png) \
+		$(use_enable tiff) \
+		$(use_enable xpm) \
+		$(use_enable allegro) \
+		--disable-directx8 \
+		--disable-directx9 \
+		$(use_enable opengl) \
+		$(use_enable sdl) \
+		$(use_enable X x11) \
+		$(use_enable X shm) \
+		$(use_enable X render) \
+		$(use_enable glut) \
+		$(use_with X x) \
+		$(use_with nvtt)
+}
+
+src_install() {
+	default
+
+	# Package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3