From d99093fb4bb5652015c06274d64083daa2439e4f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 3 Mar 2021 10:28:17 +0000
Subject: gentoo resync : 03.03.2021

---
 media-libs/dav1d/dav1d-0.8.2.ebuild | 63 +++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 media-libs/dav1d/dav1d-0.8.2.ebuild

(limited to 'media-libs/dav1d/dav1d-0.8.2.ebuild')

diff --git a/media-libs/dav1d/dav1d-0.8.2.ebuild b/media-libs/dav1d/dav1d-0.8.2.ebuild
new file mode 100644
index 000000000000..38fc32f1023f
--- /dev/null
+++ b/media-libs/dav1d/dav1d-0.8.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+SCM=""
+if [[ "${PV}" == "9999" ]]; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://code.videolan.org/videolan/dav1d"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="https://code.videolan.org/videolan/dav1d/-/archive/${PV}/${P}.tar.bz2"
+fi
+
+inherit ${SCM} meson ninja-utils multilib-minimal
+
+DESCRIPTION="dav1d is an AV1 Decoder :)"
+HOMEPAGE="https://code.videolan.org/videolan/dav1d"
+
+LICENSE="BSD-2"
+SLOT="0/5"
+IUSE="+8bit +10bit +asm"
+
+ASM_DEPEND=">=dev-lang/nasm-2.14.02"
+BDEPEND="asm? (
+		abi_x86_32? ( ${ASM_DEPEND} )
+		abi_x86_64? ( ${ASM_DEPEND} )
+	)"
+
+DOCS=( README.md doc/PATENTS THANKS.md )
+
+multilib_src_configure() {
+	local -a bits=()
+	use 8bit  && bits+=( 8 )
+	use 10bit && bits+=( 16 )
+
+	local enable_asm
+	if [[ ${MULTILIB_ABI_FLAG} == abi_x86_x32 ]]; then
+		enable_asm=false
+	else
+		enable_asm=$(usex asm true false)
+	fi
+
+	local emesonargs=(
+		-D bitdepths=$(IFS=,; echo "${bits[*]}")
+		-D enable_asm=${enable_asm}
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	eninja
+}
+
+multilib_src_test() {
+	if multilib_is_native_abi ; then
+		meson_src_test
+	fi
+}
+
+multilib_src_install() {
+	DESTDIR="${D}" eninja install
+}
-- 
cgit v1.2.3