From e9d044d4b9b71200a96adfa280848858c0f468c9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 13 Nov 2021 13:10:00 +0000
Subject: gentoo resync : 13.11.2021

---
 media-libs/avidemux-plugins/Manifest               |   2 +
 .../avidemux-plugins/avidemux-plugins-2.7.8.ebuild | 165 +++++++++++++++++++++
 2 files changed, 167 insertions(+)
 create mode 100644 media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild

(limited to 'media-libs/avidemux-plugins')

diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index 86bd1f055378..409ef74e4de3 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1,4 +1,6 @@
 AUX avidemux-plugins-2.6.20-optional-pulse.patch 743 BLAKE2B e60a7433e539d49d5bff7dea62bfda984866dd72b93158827ee5ed785d77174db3fbde9e67c9c3fdc8d652485d8e704c075811c65848ef48f78490c6a3061b7f SHA512 dcec29c63aa7eb828fc1aaf4b54edb76290e3c7655b00002efa8036f0572b1c0111c30e873b925bb606e8e672e177ba8d103100b1fb55dcc830b83e4a5556710
 DIST avidemux-2.7.6.tar.gz 21963753 BLAKE2B 6ca343f90c37844ebfd61123badccefb7327cbf500723c031257cf26500a5b6d98955568c2a9c0d182af68f162e878459a51e6049485937f9b01b4439b32e5e0 SHA512 bc60c733168d40d5b39cc7dd1f74b3f1315e9727302478ef1621e18748bad3400bcfd4d5199862c3093ad9df51385b6b2a96f0f8fedf9bf1c00060327545fb0f
+DIST avidemux-2.7.8.tar.gz 22080267 BLAKE2B a1e56856f44d56afac6ea4015f206a3f9301c025b3c8da1528165bd4c139ccc971074ac21aa05b9b3dfd6d514eabcbb375e671c8df9c9e5cae74a0a6597577c4 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82
 EBUILD avidemux-plugins-2.7.6.ebuild 4219 BLAKE2B 3c898da7cfd15fc2aba0794656c88dce1bea1c785848100ca2ee4f9f59eb4a62d30793be332c8bb5aa7f696bb684f24e62529869996ef46998f1fa6c396f6884 SHA512 d3abc534168f7a84917e6c52cbef6dba3be04aaa949ba40895241b3671a2944bf623835a928559bcd96a0960f8ae131066e7e033674a04552c6e5719b089404c
+EBUILD avidemux-plugins-2.7.8.ebuild 4351 BLAKE2B 4d02669d0adc0a4889299ca0d49707bd155ed9505a45837184c9b9e5611f53cccc1d2dc4c170aba69f559bb34c29efa0b45b187830685ec25db1a513d2a0f06b SHA512 3a13e5986634be9cf3c9dca653d916f7184b99eef4144461e328ad86359607a6954db3d94bcfc316d921333e5df9e6edcd88b80c4aefd4d971fc8e787e7e6750
 MISC metadata.xml 1314 BLAKE2B 4e36f213edce809de307062cb13962b3ecd7ff2ba50a58519a31101ba3e782812f5801f1b8904a1d39c808ba19daf1229d39c91509f32968e3b406627d636b62 SHA512 0b5ff6a059fa1b37f989c50917f417bfabaf9fcc84a42e97c21db98ef583bec48e7bec9222a0985eb4a606328a3f67462e5f43b053affd8d76e23ff97edc31c7
diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild
new file mode 100644
index 000000000000..64a8542f194c
--- /dev/null
+++ b/media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake flag-o-matic python-single-r1
+
+DESCRIPTION="Plugins for the video editor media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.7"
+IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio qt5 truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# dev-lang/spidermonkey is not required anymore
+# see https://github.com/mean00/avidemux2/blob/master/avidemux_plugins/ADM_scriptEngines/CMakeLists.txt
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
+	~media-video/avidemux-${PV}:${SLOT}[opengl?,qt5?]
+	dev-libs/libxml2:2
+	media-libs/a52dec
+	media-libs/libass:0=
+	media-libs/libmad
+	media-libs/libmp4v2
+	media-libs/libpng:0=
+	virtual/libiconv
+	aac? (
+		media-libs/faac
+		media-libs/faad2
+	)
+	aften? ( media-libs/aften )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	dcaenc? ( media-sound/dcaenc )
+	dts? ( media-libs/libdca )
+	fdk? ( media-libs/fdk-aac:0= )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	fribidi? ( dev-libs/fribidi )
+	jack? (
+		virtual/jack
+		libsamplerate? ( media-libs/libsamplerate )
+	)
+	lame? ( media-sound/lame )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk ) )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	truetype? ( media-libs/freetype:2 )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	vpx? ( media-libs/libvpx:0= )
+	x264? ( media-libs/x264:0= )
+	x265? ( media-libs/x265:0= )
+	xv? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXv
+	)
+	xvid? ( media-libs/xvid )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	oss? ( virtual/os-headers )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	!<media-libs/avidemux-plugins-${PV}
+"
+
+S="${WORKDIR}/avidemux2-${PV}"
+
+PATCHES=( "${FILESDIR}/${PN}-2.6.20-optional-pulse.patch" )
+
+src_prepare() {
+	default
+
+	# Don't reapply PATCHES during cmake_src_prepare
+	unset PATCHES
+
+	processes="buildPluginsCommon:avidemux_plugins
+		buildPluginsCLI:avidemux_plugins"
+	use qt5 && processes+=" buildPluginsQt4:avidemux_plugins"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
+	done
+}
+
+src_configure() {
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+
+		local mycmakeargs=(
+			-DAVIDEMUX_SOURCE_DIR='${S}'
+			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
+			-DFAAC="$(usex aac)"
+			-DFAAD="$(usex aac)"
+			-DALSA="$(usex alsa)"
+			-DAFTEN="$(usex aften)"
+			-DDCAENC="$(usex dcaenc)"
+			-DFDK_AAC="$(usex fdk)"
+			-DOPENCORE_AMRWB="$(usex amr)"
+			-DOPENCORE_AMRNB="$(usex amr)"
+			-DLIBDCA="$(usex dts)"
+			-DFONTCONFIG="$(usex fontconfig)"
+			-DJACK="$(usex jack)"
+			-DLAME="$(usex lame)"
+			-DNVENC="$(usex nvenc)"
+			-DOPENGL="$(usex opengl)"
+			-DOPUS="$(usex opus)"
+			-DOSS="$(usex oss)"
+			-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
+			-DQT4=OFF
+			-DFREETYPE2="$(usex truetype)"
+			-DTWOLAME="$(usex twolame)"
+			-DX264="$(usex x264)"
+			-DX265="$(usex x265)"
+			-DXVIDEO="$(usex xv)"
+			-DXVID="$(usex xvid)"
+			-DVDPAU="$(usex vdpau)"
+			-DVORBIS="$(usex vorbis)"
+			-DLIBVORBIS="$(usex vorbis)"
+			-DVPXDEC="$(usex vpx)"
+			-DUSE_EXTERNAL_LIBA52=yes
+			-DUSE_EXTERNAL_LIBASS=yes
+			-DUSE_EXTERNAL_LIBMAD=yes
+			-DUSE_EXTERNAL_LIBMP4V2=yes
+		)
+
+		use qt5 && mycmakeargs+=( -DENABLE_QT5=True )
+		use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_install
+	done
+}
-- 
cgit v1.2.3