From c8a77dfe4d3d307c1d5dd2650b7297447d8b609d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 12 Jan 2019 16:58:08 +0000
Subject: gentoo resync : 12.01.2019

---
 media-libs/alsa-oss/alsa-oss-1.1.8.ebuild | 45 +++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 media-libs/alsa-oss/alsa-oss-1.1.8.ebuild

(limited to 'media-libs/alsa-oss/alsa-oss-1.1.8.ebuild')

diff --git a/media-libs/alsa-oss/alsa-oss-1.1.8.ebuild b/media-libs/alsa-oss/alsa-oss-1.1.8.ebuild
new file mode 100644
index 000000000000..1ade777604ce
--- /dev/null
+++ b/media-libs/alsa-oss/alsa-oss-1.1.8.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+MY_P="${P/_rc/rc}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Advanced Linux Sound Architecture OSS compatibility layer"
+HOMEPAGE="https://alsa-project.org/"
+SRC_URI="mirror://alsaproject/oss-lib/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="static-libs"
+
+RDEPEND=">=media-libs/alsa-lib-${PV}[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-1.0.12-hardened.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--with-aoss
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	if ! use static-libs ; then
+		find "${ED}" -name '*.a' -delete || die
+	fi
+	find "${ED}" -name '*.la' -delete || die
+	sed -e 's:\${exec_prefix}/\\$LIB/::' -i "${ED%/}/usr/bin/aoss" || die
+}
-- 
cgit v1.2.3