From 9403c20e10161812ed5231e7fd14464ca484aa09 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 28 Jul 2022 21:05:25 +0100
Subject: gentoo auto-resync : 28:07:2022 - 21:05:25

---
 .../waifu2x-ncnn-vulkan-20220728.ebuild            | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 media-gfx/waifu2x-ncnn-vulkan/waifu2x-ncnn-vulkan-20220728.ebuild

(limited to 'media-gfx/waifu2x-ncnn-vulkan/waifu2x-ncnn-vulkan-20220728.ebuild')

diff --git a/media-gfx/waifu2x-ncnn-vulkan/waifu2x-ncnn-vulkan-20220728.ebuild b/media-gfx/waifu2x-ncnn-vulkan/waifu2x-ncnn-vulkan-20220728.ebuild
new file mode 100644
index 000000000000..640620c62e2e
--- /dev/null
+++ b/media-gfx/waifu2x-ncnn-vulkan/waifu2x-ncnn-vulkan-20220728.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="waifu2x converter using ncnn and vulkan"
+HOMEPAGE="https://github.com/nihui/waifu2x-ncnn-vulkan"
+SRC_URI="https://github.com/nihui/waifu2x-ncnn-vulkan/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/ncnn:=[vulkan]
+	media-libs/libwebp:=
+	media-libs/vulkan-loader"
+DEPEND="
+	${RDEPEND}
+	dev-util/glslang
+	dev-util/vulkan-headers"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20210521-no-lto.patch
+)
+
+src_prepare() {
+	CMAKE_USE_DIR=${S}/src
+	cmake_src_prepare
+
+	# Update all paths to match installation for models.
+	sed "/PATHSTR\|model path/s|models-|${EPREFIX}/usr/share/${PN}/models-|" \
+		-i src/main.cpp || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DGLSLANG_TARGET_DIR="${ESYSROOT}"/usr/$(get_libdir)/cmake
+		-DUSE_SYSTEM_NCNN=ON
+		-DUSE_SYSTEM_WEBP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/waifu2x-ncnn-vulkan
+
+	insinto /usr/share/${PN}
+	doins -r models/.
+
+	einstalldocs
+}
-- 
cgit v1.2.3