From fab95e98818bada1626a7723a1348f4e920d25e0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 26 Feb 2024 17:40:44 +0000
Subject: gentoo auto-resync : 26:02:2024 - 17:40:44

---
 media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild | 71 ++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild

(limited to 'media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild')

diff --git a/media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild b/media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild
new file mode 100644
index 000000000000..bca372eaed2b
--- /dev/null
+++ b/media-gfx/ueberzugpp/ueberzugpp-2.9.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Drop in replacement for ueberzug written in C++"
+HOMEPAGE="https://github.com/jstkdng/ueberzugpp/"
+SRC_URI="
+	https://github.com/jstkdng/ueberzugpp/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X opencv opengl wayland xcb-errors"
+REQUIRED_USE="xcb-errors? ( X )"
+
+RDEPEND="
+	dev-cpp/tbb:=
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/openssl:=
+	dev-libs/spdlog:=
+	media-gfx/chafa
+	media-libs/libexif
+	media-libs/libsixel
+	media-libs/vips:=
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-image
+		xcb-errors? ( x11-libs/xcb-util-errors )
+	)
+	opencv? ( media-libs/opencv:= )
+	opengl? ( media-libs/libglvnd )
+	wayland? ( dev-libs/wayland )
+	!media-gfx/ueberzug
+"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/cli11
+	dev-cpp/nlohmann_json
+	dev-cpp/range-v3
+	X? ( x11-base/xorg-proto )
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	wayland? (
+		dev-util/wayland-scanner
+		kde-frameworks/extra-cmake-modules
+	)
+"
+
+src_configure() {
+	# TODO?: wayfire plugin is skipped for now (needs wlroots which is
+	# likely to be messier), but could be handled if there is a demand
+
+	local mycmakeargs=(
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_OPENGL=$(usex opengl)
+		-DENABLE_TURBOBASE64=no # not packaged
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB_ERRORS=$(usex xcb-errors)
+		-DFETCHCONTENT_FULLY_DISCONNECTED=yes
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3