From 2480f36bfb3d39469cc44843d1fe664bd40443a3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 21 Jul 2022 14:44:25 +0100
Subject: gentoo auto-resync : 21:07:2022 - 14:44:25

---
 media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild | 67 +++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild

(limited to 'media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild')

diff --git a/media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild b/media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild
new file mode 100644
index 000000000000..2ea3a43d5863
--- /dev/null
+++ b/media-gfx/tuxpaint/tuxpaint-0.9.28.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop optfeature toolchain-funcs xdg
+
+DESCRIPTION="Drawing program designed for young children"
+HOMEPAGE="https://www.tuxpaint.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-sdl1.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${P}-sdl1
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	app-text/libpaper
+	dev-libs/fribidi
+	gnome-base/librsvg:2
+	>=media-libs/libpng-1.2:0=
+	>=media-libs/freetype-2:2
+	media-libs/libsdl[X,joystick]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer
+	media-libs/sdl-pango
+	media-libs/sdl-ttf
+	media-libs/sdl-gfx:=
+	media-gfx/libimagequant
+	sys-libs/zlib
+	x11-libs/cairo
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gperf
+	media-gfx/graphicsmagick[jpeg,png,svg]
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-Makefile.patch
+)
+
+src_compile() {
+	emake CC="$(tc-getCC)" LIBDIR="$(get_libdir)"
+}
+
+src_install() {
+	# Parallel install may break the building process
+	# See: https://bugs.gentoo.org/859169
+	emake -j1 DESTDIR="${D}" install
+	local file size
+	for file in data/images/icon[0-9]*x[0-9]*.png; do
+		size=${file##*/icon}
+		size=${size%%x*}
+		newicon -s "${size}" "${file}" tux4kids-tuxpaint.png
+	done
+	newmenu src/tuxpaint.desktop tux4kids-tuxpaint.desktop
+	docinto /usr/share/doc/${PF}
+	dodoc docs/*.txt
+	dodoc docs/en/*.txt
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "additional graphic stamps" media-gfx/tuxpaint-stamps
+}
-- 
cgit v1.2.3