From 9d8d34d0eedfd7319f905092519980bf1b4ce3e5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 11 Apr 2023 11:38:54 +0100
Subject: gentoo auto-resync : 11:04:2023 - 11:38:54

---
 media-gfx/scrot/scrot-1.9.ebuild | 61 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 media-gfx/scrot/scrot-1.9.ebuild

(limited to 'media-gfx/scrot/scrot-1.9.ebuild')

diff --git a/media-gfx/scrot/scrot-1.9.ebuild b/media-gfx/scrot/scrot-1.9.ebuild
new file mode 100644
index 000000000000..4cde5c2086b1
--- /dev/null
+++ b/media-gfx/scrot/scrot-1.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1
+
+DESCRIPTION="Screen capture utility using imlib2 library"
+HOMEPAGE="https://github.com/resurrecting-open-source-projects/scrot"
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/resurrecting-open-source-projects/${PN}"
+	inherit autotools git-r3
+else
+	SRC_URI="https://github.com/resurrecting-open-source-projects/${PN}/releases/download/${PV}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="feh LGPL-2+"
+SLOT="0"
+
+# imlib2[X] needed for imlib_create_image_from_drawable, bug #835582
+RDEPEND="
+	dev-libs/libbsd
+	media-libs/imlib2[X,filters(+),text(+)]
+	x11-libs/libXext
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXfixes
+	x11-libs/libXinerama
+	|| (
+		media-libs/imlib2[gif]
+		media-libs/imlib2[jpeg]
+		media-libs/imlib2[png]
+		media-libs/imlib2[tiff]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	elibc_musl? ( sys-libs/queue-standalone )
+"
+BDEPEND="
+	sys-devel/autoconf-archive
+	virtual/pkgconfig
+"
+
+DOCS=(
+	AUTHORS ChangeLog README.md
+)
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_install() {
+	default
+
+	newbashcomp "${FILESDIR}"/${PN}-1.7.bash-completion ${PN}
+}
-- 
cgit v1.2.3