From d99093fb4bb5652015c06274d64083daa2439e4f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 3 Mar 2021 10:28:17 +0000
Subject: gentoo resync : 03.03.2021

---
 media-gfx/nomacs/nomacs-3.16.224-r2.ebuild | 86 ++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100644 media-gfx/nomacs/nomacs-3.16.224-r2.ebuild

(limited to 'media-gfx/nomacs/nomacs-3.16.224-r2.ebuild')

diff --git a/media-gfx/nomacs/nomacs-3.16.224-r2.ebuild b/media-gfx/nomacs/nomacs-3.16.224-r2.ebuild
new file mode 100644
index 000000000000..9c6f50df1606
--- /dev/null
+++ b/media-gfx/nomacs/nomacs-3.16.224-r2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLUGIN_PKG="${PN}-plugins-$(ver_cut 1-2)"
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt-based image viewer"
+HOMEPAGE="https://nomacs.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+plugins? ( https://github.com/${PN}/${PN}-plugins/archive/$(ver_cut 1-2).tar.gz -> ${PLUGIN_PKG}.tar.gz )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86 ~amd64-linux"
+IUSE="+jpeg +opencv plugins raw +tiff zip"
+
+REQUIRED_USE="
+	raw? ( opencv )
+	tiff? ( opencv )
+"
+
+RDEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[jpeg?]
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-gfx/exiv2:=
+	opencv? ( >=media-libs/opencv-3.4:= )
+	raw? ( media-libs/libraw:= )
+	tiff? (
+		dev-qt/qtimageformats:5
+		media-libs/tiff
+	)
+	zip? ( dev-libs/quazip:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${P}/ImageLounge"
+
+DOCS=( src/changelog.txt )
+
+PATCHES=( "${FILESDIR}"/${P}-quazip1.patch )
+
+src_prepare() {
+	if use plugins ; then
+		rmdir plugins || die
+		mv -v ../../${PLUGIN_PKG} plugins || die
+		# Fix nomacs-plugins installation and search library directory
+		sed -e "s:lib/nomacs-plugins:$(get_libdir)/nomacs-plugins:" \
+			-i plugins/cmake/Utils.cmake || die
+		sed -e "s:lib/nomacs-plugins:$(get_libdir)/nomacs-plugins:" \
+			-i src/DkCore/DkPluginManager.cpp || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CODE_COV=OFF
+		-DUSE_SYSTEM_QUAZIP=ON
+		-DENABLE_TRANSLATIONS=ON
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_RAW=$(usex raw)
+		-DENABLE_TIFF=$(usex tiff)
+		-DENABLE_QUAZIP=$(usex zip)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3