From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 media-gfx/iscan/iscan-3.61.0.ebuild | 52 +++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 media-gfx/iscan/iscan-3.61.0.ebuild

(limited to 'media-gfx/iscan/iscan-3.61.0.ebuild')

diff --git a/media-gfx/iscan/iscan-3.61.0.ebuild b/media-gfx/iscan/iscan-3.61.0.ebuild
new file mode 100644
index 000000000000..3fe05c6da65a
--- /dev/null
+++ b/media-gfx/iscan/iscan-3.61.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="EPSON Image Scan v3 for Linux"
+HOMEPAGE="http://support.epson.net/linux/en/imagescanv3.php"
+
+SRC_URI="http://support.epson.net/linux/src/scanner/imagescanv3/common/imagescan_${PV}.orig.tar.gz"
+
+LICENSE="GPL-3+"
+
+SLOT="0"
+
+IUSE="graphicsmagick gui imagemagick"
+
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-libs/boost:=
+	media-gfx/sane-backends
+	media-libs/tiff
+	virtual/libusb:1
+	virtual/jpeg
+	gui? ( dev-cpp/gtkmm:= )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:= )
+		graphicsmagick? ( media-gfx/graphicsmagick:= )
+	)
+"
+RDEPEND=${DEPEND}
+
+S="${WORKDIR}/utsushi-0.$(ver_cut 2-3)"
+
+src_configure() {
+	econf \
+		$(use_with gui gtkmm) \
+		--with-jpeg \
+		$(use_with imagemagick magick) \
+		$(use_with imagemagick magick-pp) \
+		--with-tiff \
+		--with-sane \
+		--with-boost=yes
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	elog "If you encounter problems with media-gfx/xsane when scanning (e.g., bad resolution),"
+	elog "please try the built-in GUI and kde-misc/skanlite first before reporting bugs."
+}
-- 
cgit v1.2.3