From 4b19be30aa626b327c885dae62c559ec0e9fb935 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 13 Oct 2019 22:19:36 +0100
Subject: gentoo resync : 13.10.2019

---
 media-gfx/gnome-photos/Manifest                   |  2 +
 media-gfx/gnome-photos/gnome-photos-3.32.1.ebuild | 93 +++++++++++++++++++++++
 2 files changed, 95 insertions(+)
 create mode 100644 media-gfx/gnome-photos/gnome-photos-3.32.1.ebuild

(limited to 'media-gfx/gnome-photos')

diff --git a/media-gfx/gnome-photos/Manifest b/media-gfx/gnome-photos/Manifest
index a6f7fce9423b..928a81c7d55b 100644
--- a/media-gfx/gnome-photos/Manifest
+++ b/media-gfx/gnome-photos/Manifest
@@ -1,3 +1,5 @@
 DIST gnome-photos-3.30.1.tar.xz 1118728 BLAKE2B b3de35fb9c2ae7b731cf76a7b02b689997e3cf063037c49a51dbdf8bb37d9217c9bd5380bc872b984eca4e53c5996eb6370f3acc82a90e56dabe9d47999d5578 SHA512 4fa386c3d93f2b15468601e56bfcbdcc83a9e78ed5c4d0a1e51e9adf4ba313bb69e07aae52404026546dd68584e355c5e5100fc12f95fe078ccf2d6160a0a24b
+DIST gnome-photos-3.32.1.tar.xz 632688 BLAKE2B 9fa7307d1571f6c4e07d6c9700fd947e4a0ff26f8308f7b1871da817e5d80b19861d3c94a1b8ffe0daa820862ad064075641c8eb42ad66134e7c554696448932 SHA512 31a52b93c27ee603ddb314998d663d02c1cfdbc33214d2d9f977f7b66f4fc131a52cd17b274efcfb80f2fb17d7b469157e99a783cbfe76e0b872a2a75363b208
 EBUILD gnome-photos-3.30.1-r1.ebuild 1949 BLAKE2B 8f5589d46c9d807dd7855e65b04309cd9bcfd85d80fb2d203f7ea7ccabb83e0e9467037ad53fcead3adebd731fedc854325b146994e715ec3df4007ae69511ae SHA512 dbb23890e3d1e3f31cbbecc524322d5c7840fded647ce281d763a9af126aeecefb46d1890bdb262c26446aa44875fc08cef9b6ead727dacfe399633e3a7e7164
+EBUILD gnome-photos-3.32.1.ebuild 2278 BLAKE2B 3da565e8cc9df8ed03970a3d0770bc538da3e0ac6b76048004080b97fb4ca2ade1b3ae8eeb17fa5aeacaf8a80a47163b2339a1a0bcd7332c725acff165f4dc0a SHA512 fd188627c7fa8aa3c57787604e913e9e2276b4a3b3f831ed8e2e31e5a7fd4a658076f9f82feb70a75481d7478fbbaf37e929a5b9f479f062ddeaff85c33dcc99
 MISC metadata.xml 992 BLAKE2B beda29ca65d25e5d68c014fbb70fb539cf17b55d64255d6d74305d710f3979b5156eda764d75992f057416f5eb96af899b988633dd8444fcf22c6a5f73fe9b9b SHA512 3c47be6c01072a0b4845dd42b6d3561d340eb703bd9cb5c727ec24b653ab76eee38e35ba63c4cd71b93514ab0cb8bd75663febeed1901cccedfd30f223e870df
diff --git a/media-gfx/gnome-photos/gnome-photos-3.32.1.ebuild b/media-gfx/gnome-photos/gnome-photos-3.32.1.ebuild
new file mode 100644
index 000000000000..bf9760240045
--- /dev/null
+++ b/media-gfx/gnome-photos/gnome-photos-3.32.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="Access, organize and share your photos on GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Photos"
+
+LICENSE="GPL-3+ LGPL-2+ CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flickr test upnp-av"
+
+DEPEND="
+	media-libs/babl
+	>=x11-libs/cairo-1.14.0
+	>=x11-libs/gdk-pixbuf-2.36.8:2
+	>=media-libs/gegl-0.4.0:0.4[cairo,raw]
+	sci-geosciences/geocode-glib
+	>=media-libs/gexiv2-0.10.8
+	>=dev-libs/glib-2.57.2:2
+	>=net-libs/gnome-online-accounts-3.8.0:=
+	>=media-libs/grilo-0.3.5:0.3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/gtk+-3.22.16:3
+	>=dev-libs/libdazzle-3.26.0
+	>=dev-libs/libgdata-0.15.2:0=[gnome-online-accounts]
+	>=net-libs/libgfbgraph-0.2.1:0.2
+	virtual/jpeg:0
+	>=media-libs/libpng-1.6:0=
+	>=app-misc/tracker-2.0:0/2.0
+	sys-apps/dbus
+"
+# gnome-online-miners is also used for google, facebook, DLNA - not only flickr
+# but out of all the grilo-plugins, only upnp-av and flickr get used, which have USE flags here,
+# so don't pull it always, but only if either USE flag is enabled.
+# tracker-miners gschema used at runtime.
+RDEPEND="${DEPEND}
+	net-misc/gnome-online-miners[flickr?]
+	upnp-av? ( media-plugins/grilo-plugins:0.3[upnp-av] )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr] )
+	>=app-misc/tracker-miners-2
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+DOCS=() # meson installs docs itself
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e "/photos_docdir.*=.*join_paths/s/meson.project_name()/'${PF}'/" meson.build
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test dogtail)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3