From e9d044d4b9b71200a96adfa280848858c0f468c9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 13 Nov 2021 13:10:00 +0000
Subject: gentoo resync : 13.11.2021

---
 .../gnofract4d/gnofract4d-4.3_p20211108.ebuild     | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 media-gfx/gnofract4d/gnofract4d-4.3_p20211108.ebuild

(limited to 'media-gfx/gnofract4d/gnofract4d-4.3_p20211108.ebuild')

diff --git a/media-gfx/gnofract4d/gnofract4d-4.3_p20211108.ebuild b/media-gfx/gnofract4d/gnofract4d-4.3_p20211108.ebuild
new file mode 100644
index 000000000000..630443d5d244
--- /dev/null
+++ b/media-gfx/gnofract4d/gnofract4d-4.3_p20211108.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 optfeature virtualx xdg
+
+COMMIT="52410fec6cd9182048aed85e333876ddeaa9486a"
+
+DESCRIPTION="A program for drawing beautiful mathematically-based images known as fractals"
+HOMEPAGE="https://fract4d.github.io/gnofract4d/"
+SRC_URI="https://github.com/fract4d/gnofract4d/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	media-libs/libpng:0=
+	virtual/jpeg"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+	x11-libs/gtk+:3[introspection]"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		media-video/ffmpeg[vpx,zlib]
+	)"
+
+distutils_enable_tests pytest
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_prepare() {
+	sed -i -e "s:share/doc/gnofract4d/:share/doc/${PF}/:" setup.py || die
+	# test_regress.py does not provide pytest with any tests and inspecting it requires dev-python/pillow
+	rm test_regress.py || die
+	# tests hanging with virtx
+	rm fract4dgui/tests/test_{director,gtkfractal}.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile_all() {
+	if use test; then
+		ln -s "${BUILD_DIR}"/lib/fract4d/*.so fract4d/ || die
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "creating videos" media-video/ffmpeg[vpx,zlib]
+}
-- 
cgit v1.2.3