From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 media-gfx/geeqie/Manifest               |  3 +-
 media-gfx/geeqie/geeqie-1.5.1-r1.ebuild | 96 +++++++++++++++++++++++++++++++++
 media-gfx/geeqie/geeqie-9999.ebuild     |  8 +--
 3 files changed, 103 insertions(+), 4 deletions(-)
 create mode 100644 media-gfx/geeqie/geeqie-1.5.1-r1.ebuild

(limited to 'media-gfx/geeqie')

diff --git a/media-gfx/geeqie/Manifest b/media-gfx/geeqie/Manifest
index 918c4f7b69d7..55c1610421ce 100644
--- a/media-gfx/geeqie/Manifest
+++ b/media-gfx/geeqie/Manifest
@@ -1,5 +1,6 @@
 AUX geeqie-1.5.1-no_common.patch 2168 BLAKE2B 3949807b4bdd99a9283ca1ff1108fbfcc6cc034d56339875bf1d65513461ccd2da447c4923e5c1c0c14af8f204503c8b2fa72bce4faa4e270a8309cae2fd75e1 SHA512 3198780bc3840691cf2239fdf8d963bb9ead90b38fdf32d4276bd55c70fbb69d0e88f55ed901990c50907dde5b242e0f1af96ca6733ccb767b9e5e2d82ffeda9
 DIST geeqie-1.5.1.tar.xz 1587116 BLAKE2B f8742a88eefd90fb1e7e1d1365058cef190b6231fcb001faa9f110676e8403c8e5959f9af398d6fa1ddc4e4c62439728904c6c39f5095f476014a5b7b74b4d16 SHA512 265eade90afe45856855e856c5f640786ca2e3add57c3ade8ca380d075297f96bf44c6e0c4fd6eabbc2666a37f898b50d37dd2e01d77875b8a622d72d8a0e6ac
+EBUILD geeqie-1.5.1-r1.ebuild 2282 BLAKE2B 4030d0db0a455bff639f2f6ec1f3d7005240ead319a4ca8882c6417a1a6204839d698859dbd745e13a754130f47d100a3643c824367ecb4cbfc6210fb3244dd3 SHA512 077244b2b9ec5c7db5c96329abf79ef004ba8b497c87f780d5a90689bb931409906e36d56bef0e09467a0dd4ace46db608e7ad03a205d50e1d2c8b98f64e176b
 EBUILD geeqie-1.5.1.ebuild 2221 BLAKE2B d55676b39a62b450cad26488920f2af5bec2915c93e2fa25f78e843db43e136538daaab7122cf512da3917bfdbb8008459e35e1293d631a291898b5f0490d1c9 SHA512 ba79b67a40834c520140359ac316738d19b23ee641683b4a3a513a465c5101cd2fb17e1a3316b5647bcda8bb51ed93a050892bc7d14c7593aed760960920b940
-EBUILD geeqie-9999.ebuild 2271 BLAKE2B 2515899a7b95323a57e493b938dbe7108da67e6609777d469c184ba0b6adfeaa9309d91873db80157699cb2b3d8feec529b4b14bcf6a2252e2b77c0238e2bba5 SHA512 e424be1e9892eadba760355d55158ba55f303b53f42c6ad293117c1cbd3b23427f47bba0051d659a49c3dfb98062ce72c9b49873e6f37867ba85d16f964c9fcf
+EBUILD geeqie-9999.ebuild 2330 BLAKE2B 5663c258cc045098f835f35484648755e87b7223f4caee2bacc746c78bbeaa683e3fa5b7ad8bef4198853bb1628c09e103df94e8d0a98b2961d2a1a36fbbc104 SHA512 e911efd079f9b6c8455302d2f02f55de4050ecda2a17beb2ab945753c8e1c6ce0fb1947f107e4218354441b912970d5687c0ac5c72b5e87346dfc06668a6c2b2
 MISC metadata.xml 923 BLAKE2B 49de6dd7b0380b1cc74ccabbc8f84e2c55144b80612e04c4e55c82d052027882cc293a70a52f857bded73246ccbb5351df53dc1e1e08b8c2c08e630bc24f9882 SHA512 752280a5fefc097c5ca8b1fc2e9f05220aa809e45484560edca7baa68d95b0d91fa14973c321aefcdb76052dc02e405e2fb4a32e6322f04cd8223afaa6734d58
diff --git a/media-gfx/geeqie/geeqie-1.5.1-r1.ebuild b/media-gfx/geeqie/geeqie-1.5.1-r1.ebuild
new file mode 100644
index 000000000000..f0063ff9ba03
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.5.1-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+LUA_COMPAT=( lua5-{1..3} )
+
+inherit autotools lua-single xdg
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI="http://www.geeqie.org/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc exif ffmpegthumbnailer gpu-accel gtk3 jpeg lcms lirc lua map nls pdf tiff xmp"
+
+RDEPEND="
+	virtual/libintl
+	doc? ( app-text/gnome-doc-utils )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	gpu-accel? ( media-libs/clutter-gtk )
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lirc? ( app-misc/lirc )
+	lua? ( ${LUA_DEPS} )
+	map? ( media-libs/libchamplain:0.12 )
+	pdf? ( >=app-text/poppler-0.62[cairo] )
+	tiff? ( media-libs/tiff:0 )
+	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+	!xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	gpu-accel? ( gtk3 )
+	map? ( gpu-accel )"
+
+PATCHES=( "${FILESDIR}"/${P}-no_common.patch )
+
+src_prepare() {
+	default
+
+	# Remove -Werror (gcc changes may add new warnings)
+	sed -e '/CFLAGS/s/-Werror //g' -i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable debug debug-log)
+		$(use_enable ffmpegthumbnailer)
+		$(use_enable gpu-accel)
+		$(use_enable gtk3)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable lua)
+		$(use_enable lirc)
+		$(use_enable map)
+		$(use_enable nls)
+		$(use_enable pdf)
+		$(use_enable tiff)
+	)
+
+	if use exif || use xmp; then
+		myeconfargs+=( --enable-exiv2 )
+	else
+		myeconfargs+=( --disable-exiv2)
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	rm -f "${D}/usr/share/doc/${PF}/COPYING"
+	# Application needs access to the uncompressed file
+	docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Some plugins may require additional packages"
+	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+	elog "- RAW images plugin: media-gfx/ufraw"
+}
diff --git a/media-gfx/geeqie/geeqie-9999.ebuild b/media-gfx/geeqie/geeqie-9999.ebuild
index aef56eaf8bab..b9db7c038a20 100644
--- a/media-gfx/geeqie/geeqie-9999.ebuild
+++ b/media-gfx/geeqie/geeqie-9999.ebuild
@@ -2,8 +2,9 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
+LUA_COMPAT=( lua5-{1..3} )
 
-inherit autotools git-r3 xdg
+inherit autotools git-r3 lua-single xdg
 
 DESCRIPTION="A lightweight GTK image viewer forked from GQview"
 HOMEPAGE="http://www.geeqie.org"
@@ -26,7 +27,7 @@ RDEPEND="
 	jpeg? ( virtual/jpeg:0 )
 	lcms? ( media-libs/lcms:2 )
 	lirc? ( app-misc/lirc )
-	lua? ( >=dev-lang/lua-5.1:= )
+	lua? ( ${LUA_DEPS} )
 	map? ( media-libs/libchamplain:0.12 )
 	pdf? ( >=app-text/poppler-0.62[cairo] )
 	tiff? ( media-libs/tiff:0 )
@@ -39,7 +40,8 @@ BDEPEND="
 	virtual/pkgconfig
 	nls? ( sys-devel/gettext )"
 
-REQUIRED_USE="gpu-accel? ( gtk3 )
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	gpu-accel? ( gtk3 )
 	map? ( gpu-accel )"
 
 src_prepare() {
-- 
cgit v1.2.3