From 36ac65103bf5503e5bad1ecc7e8cb9e7643f6840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:49:31 +0100
Subject: Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.
---
 media-gfx/feh/feh-3.2.ebuild | 73 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 media-gfx/feh/feh-3.2.ebuild

(limited to 'media-gfx/feh/feh-3.2.ebuild')

diff --git a/media-gfx/feh/feh-3.2.ebuild b/media-gfx/feh/feh-3.2.ebuild
new file mode 100644
index 000000000000..299ad0eac2eb
--- /dev/null
+++ b/media-gfx/feh/feh-3.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs gnome2-utils xdg-utils
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="https://feh.finalrewind.org/"
+SRC_URI="https://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="feh"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="debug curl exif test xinerama"
+
+COMMON_DEPEND="media-libs/imlib2[X]
+	>=media-libs/libpng-1.2:0=
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/jpeg:0"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libXt
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		media-libs/imlib2[gif,jpeg,png]
+	)"
+
+PATCHES=( "${FILESDIR}"/${P}-debug-cflags.patch )
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}"/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+	)
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3