From 77398e424e45d9e98c1cef3c43bdadb9d56e81ef Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 10 Nov 2019 13:21:36 +0000
Subject: gentoo resync : 10.11.2019

---
 mail-filter/rspamd/rspamd-2.1.ebuild | 94 ++++++++++++++++++++++++++++++++++++
 1 file changed, 94 insertions(+)
 create mode 100644 mail-filter/rspamd/rspamd-2.1.ebuild

(limited to 'mail-filter/rspamd/rspamd-2.1.ebuild')

diff --git a/mail-filter/rspamd/rspamd-2.1.ebuild b/mail-filter/rspamd/rspamd-2.1.ebuild
new file mode 100644
index 000000000000..a44b355c466a
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-2.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils pax-utils systemd tmpfiles user
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/vstakhov/rspamd.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/vstakhov/rspamd/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Rapid spam filtering system"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="blas cpu_flags_x86_ssse3 jemalloc +jit libressl pcre2"
+
+RDEPEND="dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/libev
+	net-libs/libnsl
+	sys-apps/file
+	dev-util/ragel
+	dev-libs/libsodium
+	blas? ( sci-libs/openblas )
+	cpu_flags_x86_ssse3? ( dev-libs/hyperscan )
+	jemalloc? ( dev-libs/jemalloc )
+	jit? ( dev-lang/luajit:2 )
+	!libressl? ( dev-libs/openssl:0=[-bindist] )
+	libressl? ( dev-libs/libressl:0= )
+	pcre2? ( dev-libs/libpcre2[jit=] )
+	!pcre2? ( dev-libs/libpcre[jit=] )"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e 's/User=_rspamd/User=rspamd/g' \
+		rspamd.service \
+		|| die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+		-DENABLE_LUAJIT=$(usex jit ON OFF)
+		-DENABLE_PCRE2=$(usex pcre2 ON OFF)
+		-DENABLE_JEMALLOC=$(usex jemalloc ON OFF)
+		-DENABLE_HYPERSCAN=$(usex cpu_flags_x86_ssse3 ON OFF)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newconfd "${FILESDIR}"/rspamd.conf rspamd
+	newinitd "${FILESDIR}/rspamd-r7.init" rspamd
+	systemd_newunit rspamd.service rspamd.service
+
+	newtmpfiles "${FILESDIR}"/${PN}.tmpfile ${PN}.conf
+
+	# Remove mprotect for JIT support
+	if use jit; then
+		pax-mark m "${ED%/}"/usr/bin/rspamd-* "${ED%/}"/usr/bin/rspamadm-*
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/rspamd-r1.logrotate rspamd
+
+	diropts -o rspamd -g rspamd
+	keepdir /var/{lib,log}/rspamd
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}.conf"
+}
-- 
cgit v1.2.3