From 0a65aa74175d9ac6570321fe11725dc30c574e08 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 3 Aug 2022 13:55:12 +0100
Subject: gentoo auto-resync : 03:08:2022 - 13:55:12

---
 kde-plasma/discover/discover-5.25.3.ebuild | 90 ++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 kde-plasma/discover/discover-5.25.3.ebuild

(limited to 'kde-plasma/discover/discover-5.25.3.ebuild')

diff --git a/kde-plasma/discover/discover-5.25.3.ebuild b/kde-plasma/discover/discover-5.25.3.ebuild
new file mode 100644
index 000000000000..0f21d0949b79
--- /dev/null
+++ b/kde-plasma/discover/discover-5.25.3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.95.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+firmware flatpak telemetry"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	firmware? ( >=sys-apps/fwupd-1.5.0 )
+	flatpak? (
+		>=dev-libs/appstream-0.14.4:=
+		sys-apps/flatpak
+	)
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.25.1-tests-optional.patch" )
+
+src_prepare() {
+	ecm_src_prepare
+	# we don't need it with PackageKitBackend off
+	ecm_punt_kf_module Archive
+	# we don't do anything with this
+	sed -e "s/^pkg_check_modules.*RpmOstree/#&/" \
+		-e "s/^pkg_check_modules.*Ostree/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
+		-DWITH_KCM=OFF
+		-DBUILD_FlatpakBackend=$(usex flatpak)
+		$(cmake_use_find_package flatpak AppStreamQt)
+		-DBUILD_FwupdBackend=$(usex firmware)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest)"
+	)
+
+	ecm_src_test
+}
-- 
cgit v1.2.3