From bba7ed73af4fe3b333cb970dc40a9098e2d1c54b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 10 Oct 2022 13:34:01 +0100
Subject: gentoo auto-resync : 10:10:2022 - 13:34:00

---
 kde-frameworks/solid/solid-5.99.0.ebuild | 51 ++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 kde-frameworks/solid/solid-5.99.0.ebuild

(limited to 'kde-frameworks/solid/solid-5.99.0.ebuild')

diff --git a/kde-frameworks/solid/solid-5.99.0.ebuild b/kde-frameworks/solid/solid-5.99.0.ebuild
new file mode 100644
index 000000000000..6a92d9c81505
--- /dev/null
+++ b/kde-frameworks/solid/solid-5.99.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm frameworks.kde.org optfeature
+
+DESCRIPTION="Provider for platform independent hardware discovery, abstraction and management"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="ios nls"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	sys-apps/util-linux
+	sys-fs/udisks:2
+	virtual/libudev:=
+	ios? (
+		app-pda/libimobiledevice:=
+		app-pda/libplist:=
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ios IMobileDevice)
+		$(cmake_use_find_package ios PList)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "media player devices support" app-misc/media-player-info
+	fi
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3