From 02f2b9c649c1687088b6ccb6d30b35f519f107cf Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 8 Apr 2023 17:32:36 +0100
Subject: gentoo auto-resync : 08:04:2023 - 17:32:35

---
 kde-frameworks/ki18n/ki18n-5.105.0.ebuild | 47 +++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 kde-frameworks/ki18n/ki18n-5.105.0.ebuild

(limited to 'kde-frameworks/ki18n/ki18n-5.105.0.ebuild')

diff --git a/kde-frameworks/ki18n/ki18n-5.105.0.ebuild b/kde-frameworks/ki18n/ki18n-5.105.0.ebuild
new file mode 100644
index 000000000000..085c10ae3cf8
--- /dev/null
+++ b/kde-frameworks/ki18n/ki18n-5.105.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org python-single-r1
+
+DESCRIPTION="Framework based on Gettext for internationalizing user interface text"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	sys-devel/gettext
+	virtual/libintl
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	app-text/iso-codes
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.57.0-python.patch" )
+
+pkg_setup() {
+	ecm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# requires LANG fr_CH. bugs 823816, 879223
+	local myctestargs=( -E "(kcatalogtest|kcountrytest|kcountrysubdivisiontest)" )
+	ecm_src_test
+}
-- 
cgit v1.2.3