From 67efaff61522aeb024152ab6cddf7c40ffacb530 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 19 Oct 2023 21:52:41 +0100
Subject: gentoo auto-resync : 19:10:2023 - 21:52:41

---
 .../kfilemetadata/kfilemetadata-5.111.0.ebuild     | 67 ++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 kde-frameworks/kfilemetadata/kfilemetadata-5.111.0.ebuild

(limited to 'kde-frameworks/kfilemetadata/kfilemetadata-5.111.0.ebuild')

diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.111.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.111.0.ebuild
new file mode 100644
index 000000000000..336d6d7b24f5
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.111.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3