From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 .../kcoreaddons/kcoreaddons-5.73.0.ebuild          | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 kde-frameworks/kcoreaddons/kcoreaddons-5.73.0.ebuild

(limited to 'kde-frameworks/kcoreaddons/kcoreaddons-5.73.0.ebuild')

diff --git a/kde-frameworks/kcoreaddons/kcoreaddons-5.73.0.ebuild b/kde-frameworks/kcoreaddons/kcoreaddons-5.73.0.ebuild
new file mode 100644
index 000000000000..4e2dc414686a
--- /dev/null
+++ b/kde-frameworks/kcoreaddons/kcoreaddons-5.73.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+QTMIN=5.14.2
+inherit ecm kde.org xdg-utils
+
+DESCRIPTION="Framework for solving common problems such as caching, randomisation, and more"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="fam nls"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=dev-qt/qtcore-${QTMIN}:5[icu]
+	fam? ( virtual/fam )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-D_KDE4_DEFAULT_HOME_POSTFIX=4
+		$(cmake_use_find_package fam FAM)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bugs: 619656, 632398, 647414, 665682
+	local myctestargs=(
+		-j1
+		-E "(kautosavefiletest|kdirwatch_qfswatch_unittest|kdirwatch_stat_unittest|kformattest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	ecm_pkg_postrm
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3