From 02f2b9c649c1687088b6ccb6d30b35f519f107cf Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 8 Apr 2023 17:32:36 +0100
Subject: gentoo auto-resync : 08:04:2023 - 17:32:35

---
 .../kcoreaddons/kcoreaddons-5.105.0.ebuild         | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 kde-frameworks/kcoreaddons/kcoreaddons-5.105.0.ebuild

(limited to 'kde-frameworks/kcoreaddons/kcoreaddons-5.105.0.ebuild')

diff --git a/kde-frameworks/kcoreaddons/kcoreaddons-5.105.0.ebuild b/kde-frameworks/kcoreaddons/kcoreaddons-5.105.0.ebuild
new file mode 100644
index 000000000000..188cb9800b7e
--- /dev/null
+++ b/kde-frameworks/kcoreaddons/kcoreaddons-5.105.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org xdg-utils
+
+DESCRIPTION="Framework for solving common problems such as caching, randomisation, and more"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="dbus fam"
+
+DEPEND="
+	>=dev-qt/qtcore-${QTMIN}:5[icu]
+	virtual/libudev:=
+	dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	fam? ( virtual/fam )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qttranslations-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		-D_KDE4_DEFAULT_HOME_POSTFIX=4
+		$(cmake_use_find_package fam FAM)
+		$(cmake_use_find_package dbus Qt5DBus)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bugs: 619656, 632398, 647414, 665682
+	local myctestargs=(
+		-j1
+		-E "(kautosavefiletest|kdirwatch_qfswatch_unittest|kdirwatch_stat_unittest|kformattest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	ecm_pkg_postrm
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3