From 4df3bf9762850b34cd1ead5c80374d1a0fc3362e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 12 Jul 2021 08:41:54 +0100
Subject: gentoo resync : 12.07.2021

---
 .../breeze-icons/breeze-icons-5.84.0.ebuild        | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 kde-frameworks/breeze-icons/breeze-icons-5.84.0.ebuild

(limited to 'kde-frameworks/breeze-icons/breeze-icons-5.84.0.ebuild')

diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.84.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.84.0.ebuild
new file mode 100644
index 000000000000..904234c52640
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.84.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="test"
+
+RESTRICT+=" !test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3