From de49812990871e1705b64051c35161d5e6400269 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 24 Dec 2018 14:11:38 +0000
Subject: gentoo resync : 24.12.2018

---
 kde-apps/gwenview/gwenview-18.12.0.ebuild | 106 ++++++++++++++++++++++++++++++
 1 file changed, 106 insertions(+)
 create mode 100644 kde-apps/gwenview/gwenview-18.12.0.ebuild

(limited to 'kde-apps/gwenview/gwenview-18.12.0.ebuild')

diff --git a/kde-apps/gwenview/gwenview-18.12.0.ebuild b/kde-apps/gwenview/gwenview-18.12.0.ebuild
new file mode 100644
index 000000000000..a580d5a58ccd
--- /dev/null
+++ b/kde-apps/gwenview/gwenview-18.12.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Image viewer by KDE"
+HOMEPAGE="
+	https://www.kde.org/applications/graphics/gwenview/
+	https://userbase.kde.org/Gwenview
+"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+KEYWORDS="~amd64 ~x86"
+IUSE="activities fits kipi +mpris raw semantic-desktop X"
+
+# requires running environment
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtopengl)
+	$(add_qt_dep qtprintsupport)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	media-gfx/exiv2:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	media-libs/phonon[qt5(+)]
+	virtual/jpeg:0
+	activities? ( $(add_frameworks_dep kactivities) )
+	fits? ( sci-libs/cfitsio )
+	kipi? ( $(add_kdeapps_dep libkipi '' '' '5=') )
+	mpris? ( $(add_qt_dep qtdbus) )
+	raw? ( $(add_kdeapps_dep libkdcraw) )
+	semantic-desktop? (
+		$(add_frameworks_dep baloo)
+		$(add_frameworks_dep kfilemetadata)
+	)
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtconcurrent)
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kimageformats)
+	$(add_qt_dep qtimageformats)
+	kipi? ( media-plugins/kipi-plugins:5 )
+"
+
+src_prepare() {
+	kde5_src_prepare
+	if ! use mpris; then
+		# FIXME: upstream a better solution
+		sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package activities KF5Activities)
+		$(cmake-utils_use_find_package fits CFitsio)
+		$(cmake-utils_use_find_package kipi KF5Kipi)
+		$(cmake-utils_use_find_package raw KF5KDcraw)
+		$(cmake-utils_use_find_package X X11)
+	)
+
+	if use semantic-desktop; then
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=Baloo )
+	else
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=None )
+	fi
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version kde-apps/svgpart:${SLOT} ; then
+		elog "For SVG support, install kde-apps/svgpart:${SLOT}"
+	fi
+}
-- 
cgit v1.2.3